Ermittelt die Endkappe des Zeichenstifts
#include <GDIPlus.au3>
_GDIPlus_PenGetEndCap ( $hPen )
$hPen | Handle zu einem Zeichenstift-Objekt |
Erfolg: | Typ der Endkappe: $GDIP_LINECAPFLAT - legt ein flaches Ende fest $GDIP_LINECAPSQUARE - legt ein quadratisches Ende fest $GDIP_LINECAPROUND - legt ein rundes Ende fest $GDIP_LINECAPTRIANGLE - legt ein dreieckiges Ende fest $GDIP_LINECAPNOANCHOR - legt fest, dass die Enden der Linie nicht verankert sind $GDIP_LINECAPSQUAREANCHOR - legt fest, dass die Enden der Linie mit einem Quadrat verankert sind $GDIP_LINECAPROUNDANCHOR - legt fest, dass die Enden der Linie mit einem Kreis verankert sind $GDIP_LINECAPDIAMONDANCHOR - legt fest, dass die Enden der Linie mit einer Pfeilspitze verankert sind $GDIP_LINECAPARROWANCHOR - legt fest, dass die Enden der Linie mit einem Pfeilkopf verankert sind $GDIP_LINECAPCUSTOM - legt fest, dass die Enden der Linie eine benutzerdefinierte Endkappe haben |
Fehler: | -1 und setzt das @error Flag auf ungleich null, @extended kann den GPSTATUS Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten. |
Suche nach GdipGetPenEndCap in der MSDN Bibliothek.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
Local $hGui, $hGraphic, $hPen
; Erstellt eine GUI
$hGui = GUICreate("GDI+", 400, 300)
GUISetState(@SW_SHOW)
; Erzeugt die Ressourcen
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
$hPen = _GDIPlus_PenCreate(0xFF000000, 8)
_GDIPlus_PenSetEndCap($hPen, $GDIP_LINECAPARROWANCHOR)
; Die Endkappe des Zeichenstifts anzeigen
MsgBox($MB_SYSTEMMODAL, "Information", "Typ der Endkappe des Zeichenstifts: " & _GDIPlus_PenGetEndCap($hPen))
; Zeichnet Pfeile
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)
_GDIPlus_PenSetWidth($hPen, 6)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
_GDIPlus_PenSetWidth($hPen, 8)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 170, 390, 170, $hPen)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>Example