Funktionreferenz

_GDIPlus_PenSetAlignment

Beschreibung anzeigen in

Setzt die Ausrichtung des Zeichenstifts

#include <GDIPlus.au3>
_GDIPlus_PenSetAlignment ( $hPen [, $iAlignment = 0] )

Parameter

$hPen Handle zu einem Zeichenstift-Objekt
$iAlignment [optional] Ausrichtung des Zeichenstifts. Kann eine der folgenden sein:
0 - legt fest, dass der Zeichenstift auf die Mitte der zu zeichnenden Linie ausgerichtet wird
1 - legt fest, dass der Zeichenstift auf das innere der Kante des Polygons ausgerichtet wird, wenn ein Polygon gezeichnet wird

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Verwandte Funktionen

_GDIPlus_PenGetAlignment

Siehe auch

Suche nach GdipSetPenMode in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hPen

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Erzeugt die Ressourcen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    _GDIPlus_PenSetEndCap($hPen, $GDIP_LINECAPARROWANCHOR)
    _GDIPlus_PenSetAlignment($hPen, 1)

    ; Die Ausrichtung des Zeichenstifts anzeigen
    MsgBox($MB_SYSTEMMODAL, "Information", "Ausrichtung des Zeichenstifts: " & _GDIPlus_PenGetAlignment($hPen))

    ; Zeichnet Pfeile
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)
    _GDIPlus_PenSetWidth($hPen, 6)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth($hPen, 8)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 170, 390, 170, $hPen)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example