Funktionreferenz

_GDIPlus_PenSetDashStyle

Beschreibung anzeigen in

Setzt den Stil der Linie

#include <GDIPlus.au3>
_GDIPlus_PenSetDashStyle ( $hPen [, $iStyle = 0] )

Parameter

$hPen Handle zu einem Zeichenstift-Objekt
$iStyle [optional] Stil der Linie. Kann eine der folgenden sein:
    $GDIP_DASHSTYLESOLID - eine vollfarbige Linie
    $GDIP_DASHSTYLEDASH - eine gestrichelte Linie
    $GDIP_DASHSTYLEDOT - eine gepunktete Linie
    $GDIP_DASHSTYLEDASHDOT - eine Strich-Punkt-Linie
    $GDIP_DASHSTYLEDASHDOTDOT - eine Strich-Zwei-Punkt-Linie
    $GDIP_DASHSTYLECUSTOM - eine benutzerdefinierte Linie

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Verwandte Funktionen

_GDIPlus_PenGetDashStyle

Siehe auch

Suche nach GdipSetPenDashStyle in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hPen

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Erzeugt die Ressourcen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)

    ; Den Linien-Stil des Zeichenstifts anzeigen
    MsgBox($MB_SYSTEMMODAL, "Information", "Linien-Stil des Zeichenstifts: " & _GDIPlus_PenGetDashStyle($hPen))

    ; Zeichnet eine Linie
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example