Funktionreferenz

_GUICtrlComboBoxEx_GetItemHeight

Beschreibung anzeigen in

Ermittelt die Höhe der Items der Liste oder des Markierungsfeldes in einer ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItemHeight ( $hWnd [, $iComponent = -1] )

Parameter

$hWnd Handle des Controls
$iComponent [optional] Man kann folgende Formatstrings verwenden:
    –1 - ermittelt die Höhe des Markierungsfeldes
    0 - ermittelt die Höhe der Items der Liste

Rückgabewert

Erfolg: Die Höhe in Pixel
Fehler: -1

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBoxEx_SetItemHeight

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("ComboBoxEx: Setzt und ermittelt die Itemhöhe (v" & @AutoItVersion & ")", 500, 300)
    Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    _MemoCreate(2, 32, 396, 266, 0)
    GUISetState(@SW_SHOW)

    Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : String", $x), $x, $x)
    Next

    _MemoWrite("Setzt die Itemhöhe: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, -1, 18))
    _MemoWrite("Itemhöhe: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, -1))
    _MemoWrite("Setzt die Itemhöhe: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, 0, 20))
    _MemoWrite("Itemhöhe: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, 0))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example