Erstellt ein Imagelist Control
#include <GuiImageList.au3>
_GUIImageList_Create ( [$iCX = 16 [, $iCY = 16 [, $iColor = 4 [, $iOptions = 0 [, $iInitial = 4 [, $iGrow = 4]]]]]] )
$iCX | [optional] Breite jedes Bildes in Pixel |
$iCY | [optional] Höhe jedes Bildes in Pixel |
$iColor | [optional] Farbtiefe: 0 - verwendet Standardeinstellung 1 - verwendet eine 4 Bit DIB Sektion 2 - verwendet eine 8 Bit DIB Sektion 3 - verwendet eine 16 Bit DIB Sektion 4 - verwendet eine 24 Bit DIB Sektion 5 - verwendet eine 32 Bit DIB Sektion 6 - verwendet ein geräteabhängiges Bitmap |
$iOptions | [optional] Optionsflags. Kann eine Kombination der folgenden sein: 1 - verwendet eine Maske 2 - Die Bilder in den Listen werden gespiegelt 4 - Die Imagelist enthält einen Ausschnitt der Bilder |
$iInitial | [optional] Anzahl der Bilder die die Imagelist enthält |
$iGrow | [optional] Anzahl von Bildern auf die die Imagelist wachsen kann, wenn das System mehr Speicher für neue Bilder benötigt. Dieser Parameter stellt die Anzahl der neuen Bildern dar, die die vergrößerte Imagelist enthalten kann. |
Erfolg: | ein Handle zum neuen Control |
Fehler: | 0 |
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WinAPIGdi.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $idListview, $hImage
Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("Imagelist: Erstellen", 400, 300)
$idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
GUISetState(@SW_SHOW)
; Bilder laden
$hImage = _GUIImageList_Create(11, 11)
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0xFF0000, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0x00FF00, 11, 11))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($idListview), 0x0000FF, 11, 11))
_GUICtrlListView_SetImageList($idListview, $hImage, 1)
; Spalte hinzufügen
_GUICtrlListView_AddColumn($idListview, "Items", 120)
; Items hinzufügen
_GUICtrlListView_AddItem($idListview, "Item 1", 0)
_GUICtrlListView_AddItem($idListview, "Item 2", 1)
_GUICtrlListView_AddItem($idListview, "Item 3", 2)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example