Funktionreferenz


_GUICtrlListView_AddColumn

Beschreibung anzeigen in

Fügt dem Control eine neue Spalte hinzu

#include <GuiListView.au3>
_GUICtrlListView_AddColumn ( $hWnd, $sText [, $iWidth = 50 [, $iAlign = -1 [, $iImage = -1 [, $bOnRight = False]]]] )

Parameter

$hWnd Control-ID / Handle des Controls
$sText Spaltenüberschrift
$iWidth [optional] Breite der Spalte in Pixel
$iAlign [optional] Ausrichtung des Spaltenkopfes und des Textes der Subitems in der Spalte:
    0 - Text ist linksbündig
    1 - Text ist rechtsbündig
    2 - Text ist zentriert
$iImage [optional] 0-basierender Index eines Bildes innerhalb der Imagelist
$bOnRight [optional] Falls True erscheint des Bild rechts neben dem Text

Rückgabewert

Erfolg: Der Index der neuen Spalte
Fehler: -1

Bemerkungen

Die Ausrichtung der ersten Spalte (ganz links) ist immer linksbündig

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $hImage, $idListView

    ; Erstellt eine GUI
    GUICreate("ListView: Spalten hinzufügen", 400, 300)
    $idListView = GUICtrlCreateListView("", 2, 2, 394, 268)

    ; Aktiviert die erweiterten Control Stile
    _GUICtrlListView_SetExtendedListViewStyle($idListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Lädt die Bilder
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListView, $hImage, 1)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListView, "Spalte 1", 100)
    _GUICtrlListView_AddColumn($idListView, "Spalte 2", 100)
    _GUICtrlListView_AddColumn($idListView, "Spalte 3", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListView, "Zeile 1: Spalte 1", 0)
    _GUICtrlListView_AddSubItem($idListView, 0, "Zeile 1: Spalte 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListView, 0, "Zeile 1: Spalte 3", 2, 2)
    _GUICtrlListView_AddItem($idListView, "Zeile 2: Spalte 1", 1)
    _GUICtrlListView_AddSubItem($idListView, 1, "Zeile 2: Spalte 2", 1, 2)
    _GUICtrlListView_AddItem($idListView, "Zeile 3: Spalte 1", 2)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example