_GUICtrlListView_SetExtendedListViewStyle

Beschreibung anzeigen in

Setzt die erweiterten Stile

#include <GuiListView.au3>
_GUICtrlListView_SetExtendedListViewStyle ( $hWnd, $iExStyle [, $iExMask = 0] )

Parameter

$hWnd	Control-ID / Handle des Controls
$iExStyle	Erweiterte Stile: $LVS_EX_BORDERSELECT - Wenn ein Item markiert ist, ändert sich die Randfarbe des Items $LVS_EX_CHECKBOXES - Aktiviert Checkboxen für Items in einem ListView-Control $LVS_EX_DOUBLEBUFFER - Zeichnet mit Double-Buffering, welches Flimmern reduziert $LVS_EX_FLATSB - Aktiviert flache Scrollbalken in dem ListView $LVS_EX_FULLROWSELECT - Wenn ein Item markiert ist, werden alle Items und all seine Subitems hervorgehoben $LVS_EX_GRIDLINES - Zeigt Gitternetzlinien rund um die Items und Subitems an $LVS_EX_HEADERDRAGDROP - Aktiviert die drag-and-drop Anordnung der Spalten $LVS_EX_INFOTIP - Die $LVN_GETINFOTIP Nachricht wird gesendet, bevor ein Tooltip angezeigt wird $LVS_EX_LABELTIP - Falls nicht gesetzt, werden teilweise versteckte Labels nur in der "große Icons" Ansicht angezeigt $LVS_EX_MULTIWORKAREAS - Das Control wird seine Icons nicht automatisch einrasten bis ein oder mehrere Arbeitsflächen definiert wurden $LVS_EX_ONECLICKACTIVATE - Das Control sendet eine $LVN_ITEMACTIVATE Nachricht wenn der Benutzer ein Item anklickt $LVS_EX_REGIONAL - Setzt den Bereich des Controls um nur die Icons und den Text der Item einzubeziehen $LVS_EX_SIMPLESELECT - In der "Icons" Ansicht wandert das Statusbild des Controls nach rechts oben $LVS_EX_SUBITEMIMAGES - Erlaubt es Bilder für Subitems darzustellen $LVS_EX_TRACKSELECT - Aktiviert "hot-track" Auswahl in dem Control $LVS_EX_TWOCLICKACTIVATE - Das Control sendet eine $LVN_ITEMACTIVATE Nachricht wenn der Benutzer ein Item mit einem Doppelklick angeklickt hat $LVS_EX_UNDERLINECOLD - "Non-Hot" Items werden aktiviert und der Text wird unterstrichen dargestellt $LVS_EX_UNDERLINEHOT - "Hot" Items werden aktiviert und der Text wird unterstrichen dargestellt
$iExMask	[optional] Bestimmt welche Stile in $iExStyle beeinflusst werden sollen. Kann eine Kombination der folgenden erweiterten Stile sein. Nur der erweiterte Stil in $iExMask wird geändert. Alle anderen Stile werden so belassen wie sie sind. Falls dieser Parameter 0 ist, werden alle Stile in $iExStyle angewandt.

Rückgabewert

Gibt den vorherigen erweiterten Stil zurück

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Setzt und ermittelt die erweiterten ListView Stile (v" & @AutoItVersion & ")", 600, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Lädt die Bilder
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Spalte 0", 120)
    _GUICtrlListView_AddColumn($idListview, "Spalte 1", 120)
    _GUICtrlListView_AddColumn($idListview, "Spalte 2", 120)

    _GUICtrlListView_InsertItem($idListview, "Zeile 0: Spalte 0", -1, 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 1", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 0: Spalte 2", 2, 2)
    _GUICtrlListView_InsertItem($idListview, "Zeile 1: Spalte 0", -1, 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Zeile 1: Spalte 1", 1, 2)
    _GUICtrlListView_InsertItem($idListview, "Zeile 2: Spalte 0", -1, 2)

    MsgBox($MB_SYSTEMMODAL, "Information", "Erweiterten ListView Stile: 0x" & _GUICtrlListView_GetExtendedListViewStyle($idListview) & @CRLF & _
            _DisplayExtendStringList($idListview))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _DisplayExtendStringList($idListview)
    Local $sStyles = @CRLF & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_BORDERSELECT) = $LVS_EX_BORDERSELECT) Then $sStyles &= "$LVS_EX_BORDERSELECT" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_CHECKBOXES) = $LVS_EX_CHECKBOXES) Then $sStyles &= "$LVS_EX_CHECKBOXES" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_DOUBLEBUFFER) = $LVS_EX_DOUBLEBUFFER) Then $sStyles &= "$LVS_EX_DOUBLEBUFFER" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_FLATSB) = $LVS_EX_FLATSB) Then $sStyles &= "$LVS_EX_FLATSB" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_FULLROWSELECT) = $LVS_EX_FULLROWSELECT) Then $sStyles &= "$LVS_EX_FULLROWSELECT" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_GRIDLINES) = $LVS_EX_GRIDLINES) Then $sStyles &= "$LVS_EX_GRIDLINES" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_HEADERDRAGDROP) = $LVS_EX_HEADERDRAGDROP) Then $sStyles &= "$LVS_EX_HEADERDRAGDROP" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_INFOTIP) = $LVS_EX_INFOTIP) Then $sStyles &= "$LVS_EX_INFOTIP" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_LABELTIP) = $LVS_EX_LABELTIP) Then $sStyles &= "$LVS_EX_LABELTIP" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_MULTIWORKAREAS) = $LVS_EX_MULTIWORKAREAS) Then $sStyles &= "$LVS_EX_MULTIWORKAREAS" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_ONECLICKACTIVATE) = $LVS_EX_ONECLICKACTIVATE) Then $sStyles &= "$LVS_EX_ONECLICKACTIVATE" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_REGIONAL) = $LVS_EX_REGIONAL) Then $sStyles &= "$LVS_EX_REGIONAL" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_SIMPLESELECT) = $LVS_EX_SIMPLESELECT) Then $sStyles &= "$LVS_EX_SIMPLESELECT" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_SUBITEMIMAGES) = $LVS_EX_SUBITEMIMAGES) Then $sStyles &= "$LVS_EX_SUBITEMIMAGES" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_TRACKSELECT) = $LVS_EX_TRACKSELECT) Then $sStyles &= "$LVS_EX_TRACKSELECT" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_TWOCLICKACTIVATE) = $LVS_EX_TWOCLICKACTIVATE) Then $sStyles &= "$LVS_EX_TWOCLICKACTIVATE" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_UNDERLINECOLD) = $LVS_EX_UNDERLINECOLD) Then $sStyles &= "$LVS_EX_UNDERLINECOLD" & @CRLF & @TAB
    If (BitAND(_GUICtrlListView_GetExtendedListViewStyle($idListview), $LVS_EX_UNDERLINEHOT) = $LVS_EX_UNDERLINEHOT) Then $sStyles &= "$LVS_EX_UNDERLINEHOT" & @CRLF & @TAB
    Return $sStyles
EndFunc   ;==>_DisplayExtendStringList

Funktionreferenz

_GUICtrlListView_SetExtendedListViewStyle

Parameter

Rückgabewert

Bemerkungen

Verwandte Funktionen

Beispiel