Funktionreferenz


_GUICtrlListView_AddSubItem

Beschreibung anzeigen in

Fügt dem Control ein neues Subitem hinzu

#include <GuiListView.au3>
_GUICtrlListView_AddSubItem ( $hWnd, $iIndex, $sText, $iSubItem [, $iImage = -1] )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex 0-basierender Index des Items
$sText Text des Items oder Subitem
$iSubItem 1-basierender Index des Subitems
$iImage [optional] 0-basierender Index des Icons in der Imagelist des Controls

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_AddItem

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("ListView: SubItem hinzufügen (v" & @AutoItVersion & ")", 400, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, -1, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Lädt die Bilder
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListview), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_InsertColumn($idListview, 0, "Spalte 1", 100)
    _GUICtrlListView_InsertColumn($idListview, 1, "Spalte 2", 100)
    _GUICtrlListView_InsertColumn($idListview, 2, "Spalte 3", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListview, "Zeile 1: Spalte 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 3", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Zeile 2: Spalte 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Zeile 2: Spalte 2", 1, 2)
    _GUICtrlListView_AddItem($idListview, "Zeile 3: Spalte 1", 2)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example