Funktionreferenz

_GUICtrlListView_CreateSolidBitMap

Beschreibung anzeigen in

Erstellt ein vollfarbiges Bitmap

#include <GuiListView.au3>
_GUICtrlListView_CreateSolidBitMap ( $hWnd, $iColor, $iWidth, $iHeight )

Parameter

$hWnd Control-ID / Handle des Controls
$iColor Die Farbe des Bitmaps, dargestellt in RGB
$iWidth Die Breite des Bitmaps
$iHeight Die Höhe des Bitmaps

Rückgabewert

Gibt ein Handle zu dem Bitmap zurück

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $hImage, $idListView

    GUICreate("ListView: Erstellt ein vollfarbiges Bitmap", 400, 300)
    $idListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Lädt die Bilder
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($idListView), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListView, $hImage, 1)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListView, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListView, "Item 1", 0)
    _GUICtrlListView_AddItem($idListView, "Item 2", 1)
    _GUICtrlListView_AddItem($idListView, "Item 3", 2)

    ; Items einrücken
    _GUICtrlListView_SetItemIndent($idListView, 1, 1)
    _GUICtrlListView_SetItemIndent($idListView, 2, 2)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example