Funktionreferenz


_GUICtrlComboBoxEx_ReplaceEditSel

Beschreibung anzeigen in

Ersetzt den markierten Text in der EditBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_ReplaceEditSel ( $hWnd, $sText )

Parameter

$hWnd Handle des Controls
$sText String der den neuen Text enthält

Rückgabewert

Keine.

Bemerkungen

Falls die Nachricht zu einer ComboBox mit dem Stil $CBS_DROPDOWN oder $CBS_DROPDOWNLIST gesendet wird, schlägt die Funktion fehl.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBoxEx_SetEditText

Beispiel

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $hImage, $hCombo

    ; Erstellt eine GUI
    $hGui = GUICreate("ComboBoxEx: Ersetzt den markierten Text", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGui, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)

    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Wählt einen String in der Liste aus
    _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 149, 1))

    ; Ersetzt den markierten Text
    _GUICtrlComboBoxEx_SetEditSel($hCombo, 0, 4)

    Sleep(500)

    ; Ersetzt den markierten Text in der EditBox
    _GUICtrlComboBoxEx_ReplaceEditSel($hCombo, "ersetzt")

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example