Funktionreferenz

_GUICtrlComboBoxEx_SetExtendedUI

Beschreibung anzeigen in

Wählt entweder die Standardbenutzeroberfläche oder die erweiterte Benutzeroberfläche aus

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetExtendedUI ( $hWnd [, $bExtended = False] )

Parameter

$hWnd Handle des Controls
$bExtended [optional] legt fest, ob die Combobox erweitert angezeigt werden soll

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

Standardmäßig öffnet oder schließt die F4-Taste die Liste und die "Pfeil-runter"-Taste ändert die aktuelle Auswahl.

In einer ComboBox mit der erweiterten Benutzeroberfläche ist die F4-Taste deaktiviert und das drücken der "Pfeil-runter"-Taste öffnet die Dropdown Liste.
Außerdem wird das umstellen der ComboBox mit dem Scrollrad der Maus verhindert.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBoxEx_GetExtendedUI

Beispiel

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("ComboBoxEx: Setzt und ermittelt, ob die Standardbenutzeroberfläche oder die erweiterte Benutzeroberfläche verwendet wird (v" & @AutoItVersion & ")", 900, 300)
    Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Zufallstring", Random(1, 100, 1)), $x, $x)
    Next

    ; Ermittelt, ob die Standardbenutzeroberfläche oder die erweiterte Benutzeroberfläche verwendet wird
    MemoWrite("Erweiterte Benutzeroberfläche: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    ; Setzt die erweiterte Oberfläche
    _GUICtrlComboBoxEx_SetExtendedUI($hCombo, True)

    ; Ermittelt, ob die Standardbenutzeroberfläche oder die erweiterte Benutzeroberfläche verwendet wird
    MemoWrite("Erweiterte Benutzeroberfläche: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Gibt eine Zeile im Memo-Fenster aus
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite