Funktionreferenz


_GUICtrlComboBox_GetCueBanner

Beschreibung anzeigen in

Ermittelt den "cue banner" Text, welcher in einem Edit-Control einer Combobox angezeigt wird

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetCueBanner ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Erfolg: Der "cue banner" Text
Fehler: ein leerer String ""

Bemerkungen

Der "cue banner" ist Text, welcher in dem Edit-Control einer ComboBox dargestellt wird, wenn kein Item markiert ist

Mindestvoraussetzung Betriebssystem: Windows Vista oder neuer

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBox_SetCueBanner

Beispiel

#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo
Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("ComboBox: Setzt und ermittelt den Hinweistext (v" & @AutoItVersion & ")", 500, 296)
    Local $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    _GUICtrlComboBox_SetCueBanner($idCombo, "Wähle ein Item aus")
    $g_idMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Fügt Dateien hinzu
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Liest den Hinweistext aus und schreibt ihn ins Memo
    MemoWrite("Combobox-Hinweis: " & _GUICtrlComboBox_GetCueBanner($idCombo))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Schreibt eine Zeile in das Memo Control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite