GUICtrlCreateCombo
Erstellt eine Liste mit ausklappbarer Auswahl (ComboBox) für die GUI.
GUICtrlCreateCombo ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| text | Der Text, der in der Liste erscheinen soll. |
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
| height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard (-1) : $CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL Erzwungener Stil : $WS_TABSTOP |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. Standard ( -1) : $WS_EX_CLIENTEDGE |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um den Wert des Controls zu erhalten siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern siehe GUICtrlUpdate... Funktionen.
Unter Windows XP/2003 wird Windows selbst die Größe der geöffneten Auswahlbox anpassen. In anderen Windows-Versionen kann man diese Größe mit dem "height"-Parameter definieren, falls der Standardwert nicht ausreichend groß ist, um mindestens eine Zeile darzustellen.
Um weitere Stile zusätzlich zum Standardstil zu verwenden ist BitOR ( $GUI_SS_DEFAULT_COMBO, newstyle, ... ) zu benutzen.
Um die oben angegebenen Werte verwenden zu können, muss #include <ComboConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (Option), GUICtrlSetData, GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Example", 300, 200)
; Erstellt ein Combobox-Control.
Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185, 20)
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 170, 85, 25)
; Fügt der Combobox zusätzliche Items hinzu.
GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
Local $sComboRead = ""
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
Case $idComboBox
$sComboRead = GUICtrlRead($idComboBox)
MsgBox($MB_SYSTEMMODAL, "", "Die Combobox zeigt momentan folgendes an: " & $sComboRead, 0, $hGui)
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example