Funktionreferenz

_GUICtrlComboBox_InitStorage

Beschreibung anzeigen in

Weist den ListBox Items Speicher zu

#include <GuiComboBox.au3>
_GUICtrlComboBox_InitStorage ( $hWnd, $iNum, $iBytes )

Parameter

$hWnd Control-ID / Handle des Controls
$iNum Anzahl von hinzuzufügenden Items
$iBytes Die Menge von Speicher, welche für die Itemstring zugewiesen werden soll in Bytes

Rückgabewert

Erfolg: Die gesamte Anzahl von Items für die Speicher zugewiesen wurde
Fehler: $CB_ERRSPACE

Bemerkungen

Hilft die Initialisierung von großen ComboBoxen (über 100) zu beschleunigen.

Es können Schätzungen für die Parameter $iNum und $iBytes verwendet werden.
Falls man sich überschätzt, wird der zusätzliche Speicher trotzdem zugewiesen.
Falls man sich unterschätzt, wird die normale Zuweisung für Items verwendet, welche die angeforderte Menge überschreiten.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlComboBox_AddDir, _GUICtrlComboBox_AddString, _GUICtrlComboBox_InsertString

Beispiel

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Erstellt eine GUI
    GUICreate("ComboBox: Zuweisung von Speicher für die Items", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Speicher reservieren
    MsgBox($MB_SYSTEMMODAL, "Information", "Reservierter Speicher für: " & _GUICtrlComboBox_InitStorage($idCombo, 50, 500) & " Items")

    ; Fügt Dateien hinzu
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example