Zeigt oder versteckt die ListBox der ComboBox
#include <GuiComboBox.au3>
_GUICtrlComboBox_ShowDropDown ( $hWnd [, $bShow = False] )
$hWnd | Control-ID / Handle des Controls |
$bShow | [optional] legt fest, ob die Dropdown ListBox gezeigt wird oder nicht: True - zeigt die ListBox False - versteckt die ListBox |
Diese Funktion funktioniert nicht, wenn die ComboBox mit dem Stil $CBS_SIMPLE erstellt wurde.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_GetDroppedState
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Global $g_idMemo
Example()
Func Example()
Local $idCombo
; Erstellt eine GUI
GUICreate("ComboBox: Zeigt die ListBox", 400, 296)
$idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
$g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Fügt Dateien hinzu
_GUICtrlComboBox_BeginUpdate($idCombo)
_GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($idCombo)
; Ermittelt, ob die ListBox der ComboBox aufgeklappt ist
MemoWrite("Status des Dropdowns......: " & _GUICtrlComboBox_GetDroppedState($idCombo))
Sleep(500)
; Zeigt die ListBox
_GUICtrlComboBox_ShowDropDown($idCombo, True)
Sleep(500)
; Ermittelt, ob die ListBox der ComboBox aufgeklappt ist
MemoWrite("Status des Dropdowns......: " & _GUICtrlComboBox_GetDroppedState($idCombo))
Sleep(500)
; Versteckt die ListBox
_GUICtrlComboBox_ShowDropDown($idCombo)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
; Schreibt eine Zeile in das Memo Control
Func MemoWrite($sMessage)
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite