Funktionreferenz


_GUICtrlEdit_LineScroll

Beschreibung anzeigen in

Scrollt den Text

#include <GuiEdit.au3>
_GUICtrlEdit_LineScroll ( $hWnd, $iHoriz, $iVert )

Parameter

$hWnd Control-ID / Handle des Controls
$iHoriz legt die Anzahl von Zeichen fest, um die horizontal gescrollt werden soll.
$iVert legt die Anzahl von Zeilen fest, um die vertikal gescrollt werden soll.

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

Das Control scrollt nicht vertikal, wenn die letzte Zeile des Textes im Edit-Control erreicht wurde.
Falls die aktuelle Zeile plus die Anzahl von Zeilen (festgelegt durch den $iVert Parameter) die gesamte Anzahl von Zeilen im Edit-Control überschreitet, wird der Wert so angepasst, dass die letzte Zeile des Edit-Controls ganz nach oben in das Edit-Control gescrollt wird.

_GUICtrlEdit_LineScroll() scrollt den Text vertikal oder horizontal.
_GUICtrlEdit_LineScroll() kann verwendet werden, um bis zu dem letzten Zeichen jeder Zeile zu scrollen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlEdit_Scroll

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGui, $sText

    ; Erstellt eine GUI
    $hGui = GUICreate("Edit: Scrollt den Text", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGui)
    GUISetState(@SW_SHOW)

    ; Setzt den Text
    For $i = 1 To 50
        $sText &= $i & @CRLF
    Next
    _GUICtrlEdit_SetText($idEdit, $sText)

    ; Scrollt
    _GUICtrlStatusBar_SetText($hStatusBar, "Gescrollt: " & _GUICtrlEdit_LineScroll($idEdit, 0, _GUICtrlEdit_GetLineCount($idEdit)))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example