Funktionreferenz

_GUICtrlEdit_Undo

Beschreibung anzeigen in

Macht die letzte Edit-Control Operation in der Undo-Liste des Controls rückgängig

#include <GuiEdit.au3>
_GUICtrlEdit_Undo ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

Eine Undo-Operation kann auch rückgängig gemacht werden.
Zum Beispiel kann gelöschter Text zuerst mit _GUICtrlEdit_Undo() wiederhergestellt und dann mit _GUICtrlEdit_Undo() wieder gelöscht werden, solange keine andere Operation dazwischenkommt.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlEdit_CanUndo, _GUICtrlEdit_EmptyUndoBuffer, _GUICtrlEdit_GetModify

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idEdit

    ; Erstellt eine GUI
    GUICreate("Edit: Rückgängig machen", 400, 300)
    $idEdit = GUICtrlCreateEdit("Dies ist ein Test" & @CRLF & "Eine andere Zeile", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    _GUICtrlEdit_AppendText($idEdit, @CRLF & "An das Ende anhängen?")

    ; Rückgängig machen
    MsgBox($MB_SYSTEMMODAL, "Information", "Die letzte Aktion wird nun rückgängig gemacht")
    _GUICtrlEdit_Undo($idEdit)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example