_GUICtrlHeader_GetItemOrder

Beschreibung anzeigen in

Ermittelt, an welcher Stelle in der Headerleiste das angegebene Item erscheint

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemOrder ( $hWnd, $iIndex )

Parameter

$hWnd	Handle des Controls
$iIndex	0-basierender Index des Items

Rückgabewert

Gibt eine 0-basierende Position des Items in der Headerleiste zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Header Setzt und ermittelt die Item Reihenfolge (v" & @AutoItVersion & ")", 500, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 125)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 125)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 125)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 125)

    ; Setzt die Reihenfolge der Spalte 0
    _GUICtrlHeader_SetItemOrder($hHeader, 0, 3)

    ; Zeigt die Reihenfolge der ersten Spalte
    _MemoWrite("Reihenfolge Spalte 0: " & _GUICtrlHeader_GetItemOrder($hHeader, 0))

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Set ItemOrder to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo) ; OK also if run in different mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 1, $sFromTo)

    ; Set column 1 order
    _GUICtrlHeader_SetItemOrder($hHeader, 0, 2)

    ; Show column 0 order
    _MemoWrite("<<< Column 0 order: " & _GUICtrlHeader_GetItemOrder($hHeader, 0))

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Funktionreferenz