Funktionreferenz

_GUICtrlHeader_AddItem

Beschreibung anzeigen in

Fügt ein neues Header-Item hinzu

#include <GuiHeader.au3>
_GUICtrlHeader_AddItem ( $hWnd, $sText [, $iWidth = 50 [, $iAlign = 0 [, $iImage = -1 [, $bOnRight = False]]]] )

Parameter

$hWnd Handle des Controls
$sText Itemtext
$iWidth [optional] Itembreite
$iAlign [optional] Textausrichtung:
    0 - Text ist linksbündig
    1 - Text ist rechtsbündig
    2 - Text ist zentriert
$iImage [optional] 0-basierender Index eines Bildes innerhalb der Imagelist
$bOnRight [optional] Falls True, erscheint das Bild der Spalte rechts vom Text

Rückgabewert

Erfolg: Der Index des neuen Items
Fehler: -1

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlHeader_DeleteItem, _GUICtrlHeader_InsertItem

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGui = GUICreate("Header", 400, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGui)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 75)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 75)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 75)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 4", 75)

    _MemoWrite("Column count: " & _GUICtrlHeader_GetItemCount($hHeader))

    _MemoMsgBoxStatus("", -1, $hGui) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

Example 2 : Header Add Item to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, True)

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 3, $sFromTo)

    _GUICtrlHeader_AddItem($hHeader, "<<<Column 5", 75)

    ; Show column count
    _MemoWrite("Column count: " & _GUICtrlHeader_GetItemCount($hHeader))

    _MemoMsgBoxStatus("", Default, $hWin) ; no more action, wait GUI for closing, close also OutProcess GUI

EndFunc   ;==>Example