_GUICtrlHeader_InsertItem

Beschreibung anzeigen in

Fügt ein neues Headeritem ein

#include <GuiHeader.au3>
_GUICtrlHeader_InsertItem ( $hWnd, $iIndex, $sText [, $iWidth = 50 [, $iAlign = 0 [, $iImage = -1 [, $bOnRight = False]]]] )

Parameter

$hWnd	Handle des Controls
$iIndex	Index des Items nach dem das neue Item eingefügt werden soll. Das neue Item wird am Ende des Controls eingefügt, falls der Index größer oder gleich der Anzahl von Items im Control ist. Falls der Index 0 ist, wird das neue Item am Anfang des Controls eingefügt.
$sText	Itemtext. Siehe Bemerkungen
$iWidth	[optional] Breite des Items
$iAlign	[optional] Textausrichtung: 0 - Text ist linksbündig 1 - Text ist rechtsbündig 2 - Text ist zentriert
$iImage	[optional] 0-basierender Index eines Bilder innerhalb der Imagelist
$bOnRight	[optional] Falls True erscheint das Bild der Spalte rechts vom Text

Rückgabewert

Erfolg:	Der Index des neuen Items
Fehler:	-1

Bemerkungen

Falls ein Benachrichtigungs-Callback benötigt wird, so ist $sText = -1 (LPSTR_TEXTCALLBACK) festzulegen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Header: Item einfügen (v" & @AutoItVersion & ")", 400, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Erstellt eine Bildliste mit Bildern
    Local $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 90, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 90, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 90, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 90)

    ; Neue Spalte einfügen
    _GUICtrlHeader_InsertItem($hHeader, 1, "Spalte X", 90, 2, 0)

    _MemoMsgBoxStatus("", -1, $hGui) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Insert Item to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, False) ; OK if run in different Mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 0, $sFromTo)

    _GUICtrlHeader_InsertItem($hHeader, 2, "<<<Column Y", 100, 2, 2)
    _MemoWrite("Column #2 changed to <<<Column Y")

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Funktionreferenz