_GUICtrlHeader_GetOrderArray

Beschreibung anzeigen in

Ermittelt die aktuelle Reihenfolge der Items in einem Header-Control (links nach rechts)

#include <GuiHeader.au3>
_GUICtrlHeader_GetOrderArray ( $hWnd )

Parameter

$hWnd

Handle des Controls

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - Anzahl von Items im Array
    [1] - Item Index 1
    [2] - Item Index 2
    [n] - Item Index n

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Header: Setzt und ermittelt die Reihenfolge der Items (v" & @AutoItVersion & ")", 500, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Fügt die Spalten hinzu
    _GUICtrlHeader_AddItem($hHeader, "Spalte 0", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Spalte 3", 100)

    ; Setzt die aktuelle Reihenfolge der Items (links nach rechts)
    Local $aOrder[5] = [4, 3, 1, 2, 0]
    _GUICtrlHeader_SetOrderArray($hHeader, $aOrder)

    ; Zeigt die aktuelle Reihenfolge der Items (links nach rechts)
    $aOrder = _GUICtrlHeader_GetOrderArray($hHeader)
    For $iI = 0 To $aOrder[0]
        _MemoWrite("Index: " & $iI - 1 & ", Reihenfolge: " & $aOrder[$iI] & ' (' & _GUICtrlHeader_GetItemText($hHeader, $iI - 1) & ')')
    Next

    _MemoMsgBoxStatus("", -1, $hGUI) ; Keine weiteren Aktionen, es wird gewartet bis die GUI geschlossen wird.
EndFunc   ;==>Example

Example 2 : Header Set OrderArray to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo) ; OK if run in different Mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 0, $sFromTo)

    _MemoMsgBox($MB_SYSTEMMODAL, "Information", "About to Order the header")

    ; Set order array
    Local $aOrder[5] = [4, 0, 1, 2, 3]
    _GUICtrlHeader_SetOrderArray($hHeader, $aOrder)

    ; Show order array
    $aOrder = _GUICtrlHeader_GetOrderArray($hHeader)
    For $iI = 1 To $aOrder[0]
        _MemoWrite("Index: " & $iI - 1 & ", Order: " & $aOrder[$iI] & ' (' & _GUICtrlHeader_GetItemText($hHeader, $iI - 1) & ')')
    Next

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Funktionreferenz