Funktionreferenz

_GUICtrlListBox_Dir

Beschreibung anzeigen in

Fügt die Namen von Verzeichnissen und Dateien hinzu

#include <GuiListBox.au3>
_GUICtrlListBox_Dir ( $hWnd, $sFilePath [, $iAttributes = 0 [, $bBrackets = True]] )

Parameter

$hWnd Control-ID / Handle des Controls
$sFilePath legt den absoluten Pfad, relativen Pfad oder Dateinamen fest
$iAttributes [optional] legt die Attribute der hinzuzufügenden Dateien oder Verzeichnisse fest:
    $DDL_READWRITE - schließt normale Dateien ohne zusätzliche Attribute ein
    $DDL_READONLY - schließt schreibgeschützte Dateien ein
    $DDL_HIDDEN - schließt versteckte Dateien ein
    $DDL_SYSTEM - schließt Systemdateien ein
    $DDL_DIRECTORY - schließt Unterverzeichnisse ein
    $DDL_ARCHIVE - schließt Archivdateien ein
    $DDL_DRIVES - Alle gemappten Laufwerke werden der Liste hinzugefügt
    $DDL_EXCLUSIVE - schließt nur Dateien mit den festgelegten Attributen ein
$bBrackets [optional] schließt Klammern ein/aus wenn $DDL_DRIVES verwendet wird

Rückgabewert

Erfolg: ein 0-basierender Index des letzten hinzugefügten Namens
Fehler: -1

Bemerkungen

Wenn es unzureichenden Speicherplatz gibt um die neuen Strings zu speichern ist der Rückgabewert $LB_ERRSPACE

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListBox_InitStorage

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Erstellt eine GUI
    GUICreate("ListBox: Verzeichnis einlesen", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Fügt Dateien hinzu
    _GUICtrlListBox_BeginUpdate($idListBox)
    _GUICtrlListBox_ResetContent($idListBox)
    _GUICtrlListBox_InitStorage($idListBox, 100, 4096)
    _GUICtrlListBox_Dir($idListBox, @WindowsDir & "\win*.exe")
    _GUICtrlListBox_AddFile($idListBox, @WindowsDir & "\notepad.exe")
    _GUICtrlListBox_Dir($idListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir($idListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example