Erstellt ein List-Control für die GUI.
GUICtrlCreateList ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
text | Die Beschriftung des Controls. |
left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : $LBS_SORT, $WS_BORDER, $WS_VSCROLL Erzwungene Stile : $WS_TABSTOP, $LBS_NOTIFY |
exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. Standard ( -1) : $WS_EX_CLIENTEDGE |
Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
Fehler: | 0. |
Um den Wert des Controls zu erhalten, siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate...() Funktionen.
Die unterschiedlichen, auswählbahren Listeneinträge können mit GUICtrlSetData() gesetzt werden.
Um das horizontale Scrollen zu begrenzen, ist GUICtrlSetLimit() zu benutzen.
Um weitere Stile zusätzlich zum Standardstil zu verwenden, benutzt man BitOR($GUI_SS_DEFAULT_LIST, newstyle, ... ).
Um die oben angegebenen Werte verwenden zu können, muss #include <ListBoxConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKAUTO. (Größe und Position werden entsprechend dem neuen Fenster angepasst.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
Local $sMESSAGE = "Folgende Buttons wurden gedrückt:"
GUICreate("Meine GUI List") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird
Local $idButton_Add = GUICtrlCreateButton("Hinzufügen", 64, 32, 75, 25)
Local $idButton_Clear = GUICtrlCreateButton("Leeren", 64, 72, 75, 25)
Local $idMylist = GUICtrlCreateList("Buttons, die gedrückt wurden", 176, 32, 221, 97)
GUICtrlSetLimit(-1, 200) ; Horizontales Scrollen begrenzen
GUICtrlSetData(-1, $sMESSAGE)
Local $idButton_Close = GUICtrlCreateButton("Mein Beenden-Button", 64, 160, 175, 25)
GUISetState(@SW_SHOW)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idButton_Add
GUICtrlSetData($idMylist, "Du hast Button Nr. 1 gedrückt|")
Case $idButton_Clear
GUICtrlSetData($idMylist, "")
Case $idButton_Close
MsgBox($MB_SYSTEMMODAL, "", "Der Beenden-Button wurde gedrückt", 2)
Exit
EndSwitch
WEnd
EndFunc ;==>Example