Funktionreferenz

_GUICtrlMenu_AppendMenu

Beschreibung anzeigen in

Hängt ein neues Item an das Ende der festgelegten Menüleiste, Untermenü oder Shortcut Menü an

#include <GuiMenu.au3>
_GUICtrlMenu_AppendMenu ( $hMenu, $iFlags, $iNewItem, $vNewItem )

Parameter

$hMenu Handle des Menüs
$iFlags legt die Flags um das Erscheinungsbild und das Verhalten des neuen Menüitems:
    $MF_BITMAP - Verwendet ein Bitmap für das Menüitem
    $MF_CHECKED - Platziert ein anzuhakendes Feld neben dem Menüitem. Falls die Anwendung anzuhakende Bitmaps akzeptiert, zeigt dieses Flag ein anzuhakende Bitmap neben dem Item.
    $MF_DISABLED - Deaktiviert das Menüitem so dass es nicht ausgewählt werden kann, aber das Flag graut es nicht aus.
    $MF_ENABLED - Aktiviert das Menüitem so dass es ausgewählt werden kann und setzt es von dessen ausgegrauten Status zurück.
    $MF_GRAYED - Deaktiviert das Menüitem und graut es aus, so dass es nicht ausgewählt werden kann.
    $MF_MENUBARBREAK - Funktioniert wie $MF_MENUBREAK für eine Menülieste. Für ein Dropdown Menü, Untermenü oder Shortcut Menü wird die neue Spalte durch eine vertikale Linie von der alten getrennt.
    $MF_MENUBREAK - Platziert das Item in eine neue Zeile (für eine Menüleiste) oder in eine neue Spalte (für ein Dropdown Menü, Untermenü, oder Shortcut Menü) ohne eine trennende Spalte.
    $MF_OWNERDRAW - Legt fest, dass das Item ein selbst gezeichnetes Item ist. Bevor das Menü zum ersten Mal dargestellt wird empfängt das Menü eine $WM_MEASUREITEM Nachricht um die Breite und Höhe des Menüitems zu empfangen. Die $WM_DRAWITEM Nachricht wird zu der Fensterprozedur des eigenen Fensters gesendet, immer wenn das Menüitem aktualisiert werden muss.
    $MF_POPUP - Legt fest, dass Menüitem ein Dropdown Menü oder Untermenü öffnet. Der iNewItem Parameter legt ein Handle zu dem Dropdown Menü oder Untermenü fest. Dieses Flag wird verwendet um einen Menünamen zu einer Menüleiste hinzuzufügen oder ein Menüitem welches ein Untermenü in einem Dropdown Menü, Untermenü oder Shortcut Menü öffnet.
    $MF_SEPARATOR - Zeichnet eine horizontal teilende Linie. Dieses Flag wird nur in einem Dropdown Menü, Untermenü oder Shortcut Menü verwendet. Die Linie kann nicht ausgegraut, deaktivert oder hervorgehoben werden. Der pNewItem und iNewItem Parameter werden ignoriert.
    $MF_STRING - Legt fest, dass das Menüitem ein Textstring ist. Der pNewItem Parameter ist ein String.
    $MF_UNCHECKED - Platziert kein anzuhakendes Feld neben dem Itemm. Falls die Anwendung anzuhakende Bitmaps akzeptiert, zeigt dieses Flag ein leeres Bitmap neben dem Item.
$iNewItem Legt fest, ob entweder die ID des neuen Menüitems oder falls der $iFlags Parameter auf Popup gesetzt ist, ein Handle zu dem Dropdown Menü oder Untermenü.
$vNewItem Legt den Inhalt des neuen Menüitems fest. Die Deutung von pNewItem ist abhängig, ob der iFlags Parameter die Flags $MF_BITMAP, $MF_OWNERDRAW oder $MF_STRING einschließt:
    $MF_BITMAP - Enthält ein Bitmap Handle
    $MF_OWNERDRAW - Enthält einen anwendungsspezifischen Wert der verwendet werden kann, um zusätzliche Daten, von dem Menüitem zu erhalten. Dieser Wert ist in dem ItemData Member der Struktur, welche verwiesen ist durch den lParam Parameter von der $WM_MEASUREITEM oder $WM_DRAWITEM Nachricht, welche gesendet wird, wenn das Menü erstellt wurde oder dessen Erscheinungsbild aktualisiert wurde.
    $MF_STRING - Enthält einen String

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlMenu_InsertMenuItem

Siehe auch

Suche nach AppendMenu in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGui, $hFile, $idEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Erstellt eine GUI
    $hGui = GUICreate("Menu", 400, 300)

    ; Erstellt den Menüpunkt Datei
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&Neu", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Öffnen", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Speichern", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "&Beenden", $e_idExit)

    ; Erstellt den Menüpunkt "Bearbeiten"
    $idEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($idEdit, 0, "&Ausschneiden", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($idEdit, 1, "K&opieren", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($idEdit, 2, "&Einfügen", $e_idPaste)

    ; Erstellt den Menüpunkt Hilfe
    $hHelp = _GUICtrlMenu_CreateMenu()

    ; Erstellt das Hauptmenü
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&Datei", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Bearbeiten", 0, $idEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Hilfe", 0, $hHelp)

    ; Setzt das neue Menü
    _GUICtrlMenu_SetMenu($hGui, $hMain)
    GUISetState(@SW_SHOW)

    ; Ergänzt den Menüpunkt Über
    _GUICtrlMenu_AppendMenu($hHelp, $MF_STRING, $e_idAbout, "&Über")

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example