_GUICtrlMenu_GetItemSubMenu

Beschreibung anzeigen in

Ermittelt ein Untermenü, welches durch ein festgelegten Item aktiviert wird

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemSubMenu ( $hMenu, $iItem )

Parameter

$hMenu	Handle des Menüs
$iItem	0-basierende Position des Menüitems

Rückgabewert

Erfolg:	Ein Handle zu dem Dropdown Menü oder Untermenü, welches durch ein festgelegten Item aktiviert wird
Fehler:	0

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach GetSubMenu in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>


Global $g_idMemo

Example()

Func Example()
    Local $hGui, $hFile, $idEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Erstellt eine GUI
    $hGui = GUICreate("Menu", 400, 300)

    ; Erstellt den Menüpunkt Datei
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&Neu", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Öffnen", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Speichern", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "B&eenden", $e_idExit)

    ; Erstellt den Menüpunkt "Bearbeiten"
    $idEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($idEdit, 0, "&Ausschneiden", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($idEdit, 1, "K&opieren", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($idEdit, 2, "&Einfügen", $e_idPaste)

    ; Erstellt den Menüpunkt Hilfe
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&Über", $e_idAbout)

    ; Erstellt das Hauptmenü
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&Datei", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Bearbeiten", 0, $idEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Hilfe", 0, 0)

    ; Setzt das neue Menü
    _GUICtrlMenu_SetMenu($hGui, $hMain)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermittelt/Setzt den Menüpunkt 'Hilfe'
    MemoWrite("Handle des Menüpunkts 'Hilfe': " & _GUICtrlMenu_GetItemSubMenu($hMain, 2))
    _GUICtrlMenu_SetItemSubMenu($hMain, 2, $hHelp)
    MemoWrite("Handle des Menüpunkts 'Hilfe': " & _GUICtrlMenu_GetItemSubMenu($hMain, 2))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite