Funktionreferenz

_GUICtrlSlider_Create

Beschreibung anzeigen in

Erstellt ein Slider-Control

#include <GuiSlider.au3>
_GUICtrlSlider_Create ( $hWnd, $iX, $iY [, $iWidth = 100 [, $iHeight = 20 [, $iStyle = $TBS_AUTOTICKS [, $iExStyle = 0x00000000]]]] )

Parameter

$hWnd Handle zum Parent- oder Eigner-Fenster
$iX Horizontale Position des Controls
$iY Vertikale Position des Controls
$iWidth [optional] Breite des Controls
$iHeight [optional] Höhe des Controls
$iStyle [optional] Stile des Controls:
    $TBS_AUTOTICKS - Fügt Skalenstriche hinzu, wenn man den Wertebereich des Reglers mit der TBM_SETRANGE-Nachricht setzt.
    $TBS_BOTH - Platziert Skalenstriche auf beiden Seiten der Reglerschiene.
    $TBS_BOTTOM - Platziert Skalenstriche unter einer horizontalen Reglerschiene.
    $TBS_DOWNISLEFT - Unten gleich links und oben gleich rechts
    $TBS_ENABLESELRANGE - Die Skalenstriche in der Startposition und Endposition des markierten Bereiches werden als Dreiecke angezeigt
        (anstatt von vertikalen Strichen) und der markierte Bereich wird hervorgehoben
    $TBS_FIXEDLENGTH - erlaubt es, die Größe des Sliders mit einer $TBM_SETTHUMBLENGTH Nachricht zu verändern
    $TBS_HORZ - Definiert einen horizontalen Slider. Das ist der Standardwert.
    $TBS_LEFT - Platziert Skalenstriche auf der linken Seite einer vertikalen Reglerschiene.
    $TBS_NOTHUMB - Definiert, dass die Reglerschiene keinen Schiebeknopf hat.
    $TBS_NOTICKS - Definiert, dass die Reglerschiene keine Skalenstriche hat.
    $TBS_REVERSED - Kleinere Zahlen zeigen "höhere" und größere Zahlen zeigen "kleinere" an
    $TBS_RIGHT - Platziert Skalenstriche auf der rechten Seite einer vertikalen Reglerschiene.
    $TBS_TOP - Platziert Skalenstriche über einer horizontalen Reglerschiene.
    $TBS_TOOLTIPS - Erstellt ein Standard ToolTip-Control, welches die aktuelle Position des Sliders anzeigt
    $TBS_VERT - Definiert einen vertikalen Slider.
    Standard: $TBS_AUTOTICKS
    Erzwungen : $WS_CHILD, $WS_VISIBLE
$iExStyle [optional] Erweiterte Stile des Controls. Diese entsprechen den Standard $WS_EX_* Konstanten. Siehe Tabelle Erweiterte Stile.
Standard: $WS_EX_STATICEDGE

Rückgabewert

Erfolg: Das Handle zu dem Slider-Control.
Fehler: 0

Bemerkungen

Diese Funktion ist für erfahrene Benutzer und zum erlernen der Funktion von Controls.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlSlider_Destroy

Beispiel

Example : Erstellit mit der UDF

#include <Extras\WM_NOTIFY.au3>
#include <GuiConstantsEx.au3>
#include <GuiSlider.au3>
#include <WindowsConstants.au3>

Global $g_hSlider

Example()

Func Example()
    Local $hGui

    ; Erstellt eine GUI
    $hGui = GUICreate("Slider Erstellen (v" & @AutoItVersion & ")", 400, 296)
    $g_hSlider = _GUICtrlSlider_Create($hGui, 2, 2, 396, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    GUISetState(@SW_SHOW)

    _WM_NOTIFY_Register()

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndSlider = $g_hSlider
    If Not IsHWnd($g_hSlider) Then $hWndSlider = GUICtrlGetHandle($g_hSlider)

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Local $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndSlider
            Switch $iCode
                Case $NM_RELEASEDCAPTURE ; Das Control bemerkt, wenn die Maustaste wieder losgelassen wird
                    _WM_NOTIFY_DebugEvent("$NM_RELEASEDCAPTURE", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
                    ; Kein Rückgabewert
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY