Funktionreferenz

_GUICtrlStatusBar_GetBorders

Beschreibung anzeigen in

Ermittelt die aktuelle Breite des horizontalen und vertikalen Randes

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders ( $hWnd )

Parameter

$hWnd Handle des Controls

Rückgabewert

Erfolg: Ein Array mit dem folgenden Format:
    $aBorders[0] - Breite des horizontalen Randes
    $aBorders[1] - Breite des vertikalen Randes
    $aBorders[2] - Breite des Randes zwischen den Rechtecken
Fehler: Setzt das @error Flag auf ungleich null

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVert

Beispiel

#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("StatusBar: Ränder ermitteln (v" & @AutoItVersion & ")", 400, 300)

    Local $hStatus = _GUICtrlStatusBar_Create($hGUI)
    Local $aParts[3] = [75, 150, -1]
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermittelt die aktuelle Breite des horizontalen und vertikalen Randes
    Local $aInfo = _GUICtrlStatusBar_GetBorders($hStatus)
    MemoWrite("Breite des horizontalen Randes ...........: " & $aInfo[0])
    MemoWrite("Breite des vertikalen Randes .............: " & $aInfo[1])
    MemoWrite("Breite des Randes zwischen den Rechtecken : " & $aInfo[2])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite