Funktionreferenz


_GUICtrlTab_SetExtendedStyle

Beschreibung anzeigen in

Setzt die erweiterten Stile, welche momentan genutzt werden

#include <GuiTab.au3>
_GUICtrlTab_SetExtendedStyle ( $hWnd, $iStyle )

Parameter

$hWnd Control-ID / Handle des Controls
$iStyle momentan genutzte erweiterte Stile:
    $TCS_EX_FLATSEPARATORS - Das Control stellt Trennzeichen zwischen den Tabitems dar
    $TCS_EX_REGISTERDROP - Das Control generiert eine $TCN_GETOBJECT Nachricht um ein Fallziel abzufragen wenn ein Objekt über ein Tabitem gezogen wird.

Rückgabewert

Gibt die vorherigen erweiterten Stile zurück.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlTab_GetExtendedStyle

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    GUICreate("Tab-Control: Setzt und ermittelt den erweiterten Stil (v" & @AutoItVersion & ")", 500, 300)
    Local $idTab = GUICtrlCreateTab(2, 2, 396, 296, BitOR($TCS_BUTTONS, $TCS_FLATBUTTONS))
    GUISetState(@SW_SHOW)

    ; Fügt Tabs hinzu
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

    ; Ermittelt/Setzt den erweiterten Stil
    _GUICtrlTab_SetExtendedStyle($idTab, $TCS_EX_FLATSEPARATORS)
    MsgBox($MB_SYSTEMMODAL, "Information", "Erweiterte Stile: 0x" & Hex(_GUICtrlTab_GetExtendedStyle($idTab)))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example