GUICtrlCreateTab
Erzeugt eine Karteireiterauswahl (Tab) für die GUI.
GUICtrlCreateTab ( left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
| height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : Keine. Erzwungene Stile : $TCS_TOOLTIPS, $WS_TABSTOP, $WS_CLIPSIBLINGS |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Ein Tab-Control ist ein Control das nur TabItem-Controls enthält. Andere Controls sollen innerhalb dieses TabItems mittels GUICtrlCreate...-Funktionen erzeugt werden (siehe Beispiele). Es ist wichtig die Tab-Struktur mit einem TabItem-Control mit leerem Text abzuschließen. ( GUICtrlCreateTabItem("") )
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate...() Funktionen.
Um weitere Stile zusätzlich zum Standardstil zu verwenden, benutzt man BitOR($GUI_SS_DEFAULT_TAB, newstyle, ... ).
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
Ein GUI-Fenster kann nur ein einzelnes Tab-Menü(Control) beinhalten. Aber ein Skript kann verschiedene Fenster mit je einem Tab-Menü darin erzeugen.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (Option), GUICtrlCreate..., GUICtrlCreateTabItem, GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
Example()
Func Example()
GUICreate("Meine GUI mit Tabs") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird
GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)
GUICtrlCreateTab(10, 10, 200, 100)
GUICtrlCreateTabItem("Tab0")
GUICtrlCreateLabel("Beschriftung0", 30, 80, 80, 20)
GUICtrlCreateButton("OK0", 20, 50, 50, 20)
GUICtrlCreateInput("Standard", 80, 50, 70, 20)
GUICtrlCreateTabItem("Tab----1")
GUICtrlCreateLabel("Beschriftung1", 30, 80, 80, 20)
GUICtrlCreateCombo("", 20, 50, 60, 120)
GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon") ; Standard Jon
GUICtrlCreateButton("OK1", 80, 50, 50, 20)
GUICtrlCreateTabItem("Tab2")
GUICtrlSetState(-1, $GUI_SHOW) ; Lässt die GUI anzeigen
GUICtrlCreateLabel("Beschriftung2", 30, 80, 80, 20)
GUICtrlCreateButton("OK2", 140, 50, 50)
GUICtrlCreateTabItem("") ; Beendet die Tab Definition
GUICtrlCreateLabel("Beschriftung3", 20, 130, 80, 20)
GUISetState(@SW_SHOW)
Local $idMsg
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
$idMsg = GUIGetMsg()
If $idMsg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
EndFunc ;==>Example