Erstellt ein Eingabe-Control für die GUI.
GUICtrlCreateInput ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
text | (Vorgeblendeter) Text in dem Input-Control. |
left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
width | [optional] Die Breite des Controls (voreingestellt ist die zuvor verwendete Breite). |
height | [optional] Die Höhe des Controls (voreingestellt ist die zuvor verwendete Höhe). |
style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : $ES_LEFT, $ES_AUTOHSCROLL Erzwungene Stile : $WS_TABSTOP, nur wenn nicht $ES_READONLY gesetzt wurde. $ES_MULTILINE wird immer zurückgesetzt. |
exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. Standard ( -1) : $WS_EX_CLIENTEDGE |
Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
Fehler: | 0. |
Um den Wert des Controls zu erhalten, siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate...() Funktionen.
Um ein Input-Control zur Eingabe von Passwörtern zu erzeugen (die Eingabe wird unsichtbar durch einen Stern dargestellt), benutzt man den Stil $ES_AUTOHSCROLL + $ES_PASSWORD.
Will man per drag & drop einen Dateinamen auf ein solches Control ziehen, muss man nur den erweiterten Stil WS_EX_ACCEPTFILES auf den Befehl GUICreate() anwenden und den Status auf $GUI_DROPACCEPTED setzen.
Hat man mehrere Drag and Drop-Dateien in diesem Control, kann man die durch "|" getrennte Filenamen, mit GUICtrlRead() auslesen.
Um die oben angegebenen Werte verwenden zu können, muss #include <EditConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
Um einen vordefinierten grauen Text für ein Input-Control vorzugeben, kann "GUICtrlSendMsg($cInput, $EM_SETCUEBANNER, False, "zu drückende Taste (optional)")" verwendet werden.
Der Text wird entfernt sobald das Control angeklickt wird. Wird jedoch nichts in das Control geschrieben und wieder ein anderes Control angeklickt, so erscheint der Text wieder.
- - - - - - - - Erklärung der Controls - - - - - - - -
GUICoordMode (Option), GUICtrlCreateUpdown, GUICtrlRead, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("Meine GUI die Dateien akzeptiert", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, $WS_EX_ACCEPTFILES)
Local $idFile = GUICtrlCreateInput("", 10, 5, 300, 20)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlCreateInput("", 10, 35, 300, 20) ; Akzeptiert kein Drag&Drop von Dateien
Local $idBtn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)
GUISetState(@SW_SHOW)
$idMsg = 0
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idBtn
ExitLoop
EndSwitch
WEnd
MsgBox($MB_SYSTEMMODAL, "Drag&Drop Datei", GUICtrlRead($idFile))
EndFunc ;==>Example