Funktionreferenz

_GUICtrlToolbar_EnableButton

Beschreibung anzeigen in

Aktiviert oder deaktiviert einen festgelegten Button

#include <GuiToolBar.au3>
_GUICtrlToolbar_EnableButton ( $hWnd, $iCommandID [, $bEnable = True] )

Parameter

$hWnd Handle des Controls
$iCommandID Button Command ID
$bEnable [optional] Aktivierungsflag:
    True - Button wird aktiviert
    False - Button wird deaktiviert

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_HideButton

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>


Example()

Func Example()
    Local $hGui, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    GUISetState(@SW_SHOW)

    ; Fügt die Standard Systembitmaps hinzu
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Deaktiviert den Hilfe Button
    _GUICtrlToolbar_EnableButton($hToolbar, $idHelp, False)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example