#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar: Ermittelt das begrenzende Rechteck für einen festgelegten Toolbar Button (v" & @AutoItVersion & ")", 700, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
    GUISetState(@SW_SHOW)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

    ; Zeigt das Rechteck des Speichern-Buttons
    Local $tRECT = _GUICtrlToolbar_GetButtonRectEx($hToolbar, $e_idSave)
    _MemoWrite("Rechteck des Speichern-Buttons")
    _MemoWrite("----------------")
    _MemoWrite("Links .: " & DllStructGetData($tRECT, "Left"))
    _MemoWrite("Oben ..: " & DllStructGetData($tRECT, "Top"))
    _MemoWrite("Rechts : " & DllStructGetData($tRECT, "Right"))
    _MemoWrite("Unten .: " & DllStructGetData($tRECT, "Bottom"))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example