Ermittelt einen String von der Stringsammlung
#include <GuiToolBar.au3>
_GUICtrlToolbar_GetString ( $hWnd, $iIndex )
$hWnd | Handle des Controls |
$iIndex | Index des Strings |
Die Nachricht gibt den festgelegten String von der Stringsammlung des Controls zurück. Dies ist nicht unbedingt der Textstring der momentan auf dem Button dargestellt wird.
Um den aktuellen Textstring eines Buttons zu erhalten ist _GUICtrlToolbar_GetButtonText() zu verwenden.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlToolbar_AddString, _GUICtrlToolbar_GetButtonText
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Erstellt eine GUI
Local $hGUI = GUICreate("Toolbar: String ermitteln (v" & @AutoItVersion & ")", 400, 300)
Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
$g_idMemo = GUICtrlCreateEdit("", 2, 45, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)
; Fügt die Standard Systembitmaps hinzu
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Fügt Strings hinzu
Local $aStrings[4]
$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Neu")
$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Öffnen")
$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Speichern")
$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Hilfe")
; Fügt die Buttons hinzu
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])
; Ermittelt den Text von String 2
MemoWrite("Text von String 2 .: " & _GUICtrlToolbar_GetString($hToolbar, 2))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite