Funktionreferenz


_GUICtrlToolbar_GetStyle

Beschreibung anzeigen in

Ermittelt die Stile die momentan in einem Toolbar-Control verwendet werden

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetStyle ( $hWnd )

Parameter

$hWnd Handle des Controls

Rückgabewert

Gibt die Stile des Controls zurück.. Kann eine Kombination der folgenden sein :
    $TBSTYLE_TOOLTIPS - Erstellt ein ToolTip-Control
    $TBSTYLE_WRAPABLE - Erstellt eine Toolbar die mehrere Zeilen mit Buttons haben kann
    $TBSTYLE_ALTDRAG - Erlaubt es dem Benutzer die Position der Buttons durch ziehen zu verändern
    $TBSTYLE_FLAT - Erstellt eine flache Toolbar
    $TBSTYLE_LIST - Erstellt eine flache Toolbar mit dem Buttontext rechts vom Bitmap
    $TBSTYLE_CUSTOMERASE - Sendet $NM_CUSTOMDRAW Nachrichten wenn $WM_ERASEBKGND verursacht werden
    $TBSTYLE_REGISTERDROP - Sendet $TBN_GETOBJECT Nachrichten um Zielobjekte anzufordern
    $TBSTYLE_TRANSPARENT - Erstellt eine transparente Toolbar

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_SetStyle

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGui, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Setzt den Stil des Controls
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))

    ; Fügt die Standard-Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Zeigt den Stil des Controls
    MemoWrite("Stil der Toolbar .: 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite