Funktionreferenz

_GUICtrlToolbar_InsertButton

Beschreibung anzeigen in

Fügt einen Button ein

#include <GuiToolBar.au3>
_GUICtrlToolbar_InsertButton ( $hWnd, $iIndex, $iID, $iImage [, $sText = "" [, $iStyle = 0 [, $iState = 4 [, $iParam = 0]]]] )

Parameter

$hWnd Handle des Controls
$iIndex 0-basierender Index des Buttons
$iID Command ID
$iImage 0-basierender Bilderindex
$sText [optional] Buttontext
$iStyle [optional] Buttonstil. Kann eine Kombination der folgenden sein:
    $BTNS_AUTOSIZE - Das Toolbar-Control sollte nicht die Standardbreite des Buttons verwenden
    $BTNS_BUTTON - Standardbutton
    $BTNS_CHECK - Schaltet zwischen gedrückt und nicht gedrückt hin und her
    $BTNS_CHECKGROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
    $BTNS_DROPDOWN - Erstellt ein Dropdown Button welcher eine Liste darstellt
    $BTNS_GROUP - Button der solange gedrückt dargestellt wird bis ein anderer Button in der Gruppe gedrückt wird
    $BTNS_NOPREFIX - Der Buttontext hat keinen Shortcutbuchstaben
    $BTNS_SEP - Erstellt einen Trenner
    $BTNS_SHOWTEXT - legt fest, dass der Buttontext angezeigt werden soll
    $BTNS_WHOLEDROPDOWN - legt fest, dass der Button einen Dropdown Pfeil hat
$iState [optional] Buttonstatus. Kann eine Kombination der folgenden sein:
    $TBSTATE_CHECKED - Der Button hat den $TBSTYLE_CHECK Stil und ist angeklickt
    $TBSTATE_PRESSED - Der Button ist angeklickt
    $TBSTATE_ENABLED - Der Button akzeptiert Benutzereingaben
    $TBSTATE_HIDDEN - Der Button ist nicht sichtbar und empfängt keine Benutzereingaben
    $TBSTATE_INDETERMINATE - Der Button ist ausgegraut
    $TBSTATE_WRAP - Dem Button folgt ein Zeilenumbruch
    $TBSTATE_ELLIPSES - Der Text des Buttons ist ausgeschnitten und eine Ellipse wird angezeigt
    $TBSTATE_MARKED - Der Button ist markiert
$iParam [optional] anwendungsspezifischer Wert

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

Fügt den neuen Button links vom Button $iIndex ein

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_AddButton

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>


Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar: Button einfügen (v" & @AutoItVersion & ")", 400, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

    ; Fügt die Standard Systembitmaps hinzu
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Fügt die Buttons hinzu
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
    _GUICtrlToolbar_InsertButton($hToolbar, 0, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_InsertButton($hToolbar, 1, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_InsertButton($hToolbar, 2, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_InsertButton($hToolbar, 4, $idHelp, $STD_HELP)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example