Funktionreferenz


_GUICtrlToolbar_SetButtonBitMap

Beschreibung anzeigen in

Setzt den Index des Bitmaps der mit einem Button verknüpft ist

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonBitMap ( $hWnd, $iCommandID, $iIndex )

Parameter

$hWnd Handle des Controls
$iCommandID Button Command ID
$iIndex 0-basierender Index eines Bilder aus der Imagelist

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetButtonBitmap

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar: Setzt und ermittelt den Index des Bitmaps (v" & @AutoItVersion & ")", 500, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Zeigt den Index des Speichern-Bitmaps
    MsgBox($MB_SYSTEMMODAL, "Information", "Ändert das Speichern-Bitmap in das Drucken-Bitmap")
    _GUICtrlToolbar_SetButtonBitMap($hToolbar, $e_idSave, $STD_PRINT)
    MsgBox($MB_SYSTEMMODAL, "Information", "Index des Speichern-Bitmap: " & _GUICtrlToolbar_GetButtonBitmap($hToolbar, $e_idSave))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example