Setzt die Informationen zu einem Farbenschema
#include <GuiToolBar.au3>
_GUICtrlToolbar_SetColorScheme ( $hWnd, $iHighlight, $iShadow )
$hWnd | Handle des Controls |
$iHighlight | hervorgehobene Farbe |
$iShadow | Schattenfarbe |
Das Control verwendet Informationen über das Farbenschema, wenn es 3D Items im Control zeichnet
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlToolbar_GetColorScheme
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Erstellt eine GUI
Local $hGUI = GUICreate("Toolbar: Setzt und ermittelt die Farbe (v" & @AutoItVersion & ")", 500, 300)
Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
$g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)
; Fügt die Standard Systembitmaps hinzu
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Fügt die Buttons hinzu
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Ändert das Farbschema
_GUICtrlToolbar_SetColorScheme($hToolbar, 0x00ffff, 0x800000)
; Zeigt das Farbschema
Local $aScheme = _GUICtrlToolbar_GetColorScheme($hToolbar)
MemoWrite("Hervorgehoben: " & '0x' & Hex($aScheme[0], 6))
MemoWrite("Schatten: " & '0x' & Hex($aScheme[1], 6))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite