Funktionreferenz


_GUICtrlToolbar_SetIndeterminate

Beschreibung anzeigen in

Setzt oder entfernt den "deaktiviert"-Status des festgelegten Buttons

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetIndeterminate ( $hWnd, $iCommandID [, $bState = True] )

Parameter

$hWnd Handle des Controls
$iCommandID Button Command ID
$bState [optional] True falls deaktiviert, sonst False

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>


Example()

Func Example()
    Local $hGui, $hToolbar, $aStrings[4]
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    GUISetState(@SW_SHOW)

    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Fügt Strings hinzu
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Neu Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Öffnen Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Speichern Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Hilfe Button")

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Setzt den Status des Speichern Buttons
    MsgBox($MB_SYSTEMMODAL, "Information", "Speichern Button deaktiviert: " & _GUICtrlToolbar_IsButtonIndeterminate($hToolbar, $e_idSave))
    _GUICtrlToolbar_SetIndeterminate($hToolbar, $e_idSave)
    MsgBox($MB_SYSTEMMODAL, "Information", "Speichern Button deaktiviert: " & _GUICtrlToolbar_IsButtonIndeterminate($hToolbar, $e_idSave))

    ; Die Schleife wiederholt sich, bis der Benutzer eine Beenden-Aktion auslöst
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example