Funktionreferenz


_GUICtrlToolbar_SetInsertMark

Beschreibung anzeigen in

Setzt die aktuelle Einfügemarke für die Toolbar

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetInsertMark ( $hWnd, $iButton [, $iFlags = 0] )

Parameter

$hWnd Handle des Controls
$iButton 0-basierender Index der Einfügemarke. Falls -1 gibt es keine Einfügemarke.
$iFlags [optional] Definiert, wo die Einfügemarke in Relation zu $iButton liegt:
    0 - links vom festgelegten Button
    1 - rechts vom festgelegten Button
    2 - Im Hintergrund der Toolbar

Rückgabewert

Keine.

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetInsertMark

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar: Setrzt und ermittelt die Einfügemarke (v" & @AutoItVersion & ")", 500, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Setzt die aktuelle Einfügemarke
    _GUICtrlToolbar_SetInsertMarkColor($hToolbar, 0xFF0000)
    _GUICtrlToolbar_SetInsertMark($hToolbar, 1, 1)

    ; Zeigt die aktuelle Einfügemarke
    Local $aMark = _GUICtrlToolbar_GetInsertMark($hToolbar)
    MemoWrite("Index .............................: " & $aMark[0])
    MemoWrite("Position im Verhältnis zum Button .: " & $aMark[1])
    MemoWrite("Farbe für die Einfügemarke ........: 0x" & Hex(_GUICtrlToolbar_GetInsertMarkColor($hToolbar), 6))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite