Funktionreferenz

_GUICtrlToolbar_SetPadding

Beschreibung anzeigen in

Legt die Einrückung fest

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetPadding ( $hWnd, $iCX, $iCY )

Parameter

$hWnd Handle des Controls
$iCX Die horizontale Einrückung in Pixel
$iCY Die vertikale Einrückung in Pixel

Rückgabewert

Gibt die vorherige Einrückung in low word und die vorherige vertikale Einrückung in high word zurück

Bemerkungen

Die Einrückwerte werden verwendet um eine leere Fläche zwischen der Kante des Buttons und des Buttonbildes und/oder Text herzustellen.
Der horizontale Einrückwert wird auf die rechte und linke Seite des Buttons und der vertikale Einrückwert auf die obere und untere Seite des Buttons angewandt.
Die Einrückung wird nur auf Buttons angewandgt, die den Stil $BTNS_AUTOSIZE besitzen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetPadding

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGui, $hToolbar, $aPad
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    $hGui = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGui)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Setzt die horizontale und vertikale Einrückung
    _GUICtrlToolbar_SetPadding($hToolbar, 2, 3)

    ; Zeigt die horizontale und vertikale Einrückung
    $aPad = _GUICtrlToolbar_GetPadding($hToolbar)
    MemoWrite("Horizontale Einrückung : " & $aPad[0])
    MemoWrite("Vertikale Einrückung ..: " & $aPad[1])

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite