Ermittelt das aktuell markierte Item
#include <GuiTreeView.au3>
_GUICtrlTreeView_GetSelection ( $hWnd )
$hWnd | Control-ID / Handle des Controls |
Erfolg: | das Handle zu dem aktuell markierten Item oder 0, wenn kein Item markiert ist |
Fehler: | 0 falls kein Item markiert ist |
Durch diese Funktion kann nur der Status welcher durch _GUICtrlTreeView_SelectItem oder _GUICtrlTreeView_SelectItemByIndex gesetzt wurde ermittelt werden.
Es kann nur ein Item ausgewählt sein.
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView: Ermittelt das Handle des markierten Items (v" & @AutoItVersion & ")", 500, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
_GUICtrlTreeView_BeginUpdate($idTreeView)
Local $aidItem[10]
For $x = 0 To 9
$aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Item", $x), $idTreeView)
For $y = 1 To Random(2, 10, 1)
GUICtrlCreateTreeViewItem(StringFormat("[%02d] Neues Child", $y), $aidItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($idTreeView)
Local $iRand = Random(0, 9, 1)
_GUICtrlTreeView_SelectItem($idTreeView, $aidItem[$iRand])
MsgBox($MB_SYSTEMMODAL, "Information", "Handle des markierten Items: " & _GUICtrlTreeView_GetSelection($idTreeView))
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example