Funktionreferenz

_GUIImageList_DrawEx

Beschreibung anzeigen in

Zeichnet ein Item aus einer Imagelist an dem festgelegten Bereich

#include <GuiImageList.au3>
_GUIImageList_DrawEx ( $hWnd, $iIndex, $hDC, $iX, $iY [, $iDX = 0 [, $iDY = 0 [, $iRGBBk = 0xFFFFFFFF [, $iRGBFg = 0xFFFFFFFF [, $iStyle = 0]]]]] )

Parameter

$hWnd Handle der Imagelist
$iIndex 0-basierender Index des zu zeichnenden Bildes
$hDC Handle zu dem Ort
$iX X Koordinate wo das Bild gezeichnet werden soll
$iY Y Koordinate wo das Bild gezeichnet werden soll
$iDX [optional] Die Breite des Abschnitts des Bildes um relativ zu der oberen linken Ecke des Bildes zu zeichnen.
Falls $iDX und $iDY 0 sind, zeichnet diese Funktion das komplette Bild. Diese Funktion prüft nicht, ob die Parameter gültig sind.
$iDY [optional] Die Höhe des Abschnitts des Bildes um relativ zu der oberen linken Ecke des Bildes zu zeichnen.
Falls $iDX und $iDY 0 sind, zeichnet diese Funktion das komplette Bild. Diese Funktion prüft nicht, ob die Parameter gültig sind.
$iRGBBk [optional] Die Hintergrundfarbe des Bildes. Dieser Parameter kann anwendungsspezifischer RGB Wert sein oder einer der folgenden Werte:
    $CLR_NONE - Keine Hintergrundfarbe. Das Bild wird transparent gezeichnet.
    $CLR_DEFAULT - Die Standard Hintergrundfarbe. Das Bild wird durch Benutzen der Hintergrundfarbe des Bildes gezeichnet.
$iRGBFg [optional] Die Vordergrundfarbe des Bildes. Dieser Parameter kann anwendungsspezifischer RGB Wert sein oder einer der folgenden Werte:
    $CLR_NONE - Keine Mischfarbe. Das Bild wird mit der Farbe des Zielbildes gemischt.
    $CLR_DEFAULT - Die Standard Vordergrundfarbe. Das Bild wird durch Benutzen der Systemfarbe für hervorgehobene Objekte als Vordergrundfarbe gezeichnet.
$iStyle [optional] Zeichenstil und Overlay-Bild:
    1 - Zeichnet das Bild transparent durch Benutzung einer Maske unabhängig von der Hintergrundfarbe
    2 - Zeichnet das Bild, vermischt mit 25 Prozent von dem Systemfarbe für das Hervorheben
    4 - Zeichnet das Bild, vermischt mit 50 Prozent von dem Systemfarbe für das Hervorheben
    8 - Zeichnet die Maske

Rückgabewert

Erfolg: True
Fehler: False

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUIImageList_Draw

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>
#include <WinAPIGdiDC.au3>

Example()

Func Example()
    Local $hImage, $hGui, $hDC

    $hGui = GUICreate("ImageList: ein Item aus einer Imagelist an dem festgelegten Bereich zeichnen", 400, 300)
    GUISetState(@SW_SHOW)

    ; Lädt die Bilder
    $hImage = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0xFF0000, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x00FF00, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGui, 0x0000FF, 32, 24))

    ; Zeichnet die Bilder
    $hDC = _WinAPI_GetDC($hGui)
    _GUIImageList_DrawEx($hImage, 0, $hDC, 4, 4)
    _GUIImageList_DrawEx($hImage, 1, $hDC, 40, 4)
    _GUIImageList_DrawEx($hImage, 2, $hDC, 76, 4)

    _WinAPI_ReleaseDC($hGui, $hDC)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example