Prüft, ob eine Taste gedrückt wurde

#include <Misc.au3>
_IsPressed ( [$vKey = Default [, $vDLL = Default [, $bCheckModifierKey = False]]] )

Parameter

Rückgabewert

Bemerkungen

Falls diese Funktion wiederholt aufgerufen wird, sollte die Datei 'user32.dll' geöffnet werden und durch ein Handle übergeben werden.
Es ist noch zu beachten, dass das Handle am Ende des Skripts mithilfe der Funktion DllClose() geschlossen wird.
Wenn Sie $vDLL = Default verwenden und das AutoIt-Skript nicht beenden und die Verwendung von _IsPressed(...) einstellen,
rufen Sie dann _IsPressed() auf, um den intern verwendeten Handle zu schließen.

Wenn $vKey eine Zeichenfolge oder ein $VK_* ist, wie in „WinAPIvkeysConstants.au3” definiert, dann
gibt _IsPressed() 1 zurück, bis die Taste gedrückt wird.
    Selbst kurze Tastendrücke können zu mehreren Rückgaben innerhalb einer Schleife führen.
Wenn der aufgerufene Code keine blockierende Funktion (wie MsgBox) enthält und der Benutzer keine Mehrfachrückgaben benötigt,
sollte das Skript warten, bis _IsPressed() 0 zurückgibt, bevor es fortfährt (siehe Beispiel 1)

Wenn $vKey ein Array ist, kehrt die Funktion zurück, wenn die Taste gedrückt wird.
Der Rückgabewert ist 1, wenn $vKey[0] gedrückt wird, 2, wenn $vKey[1] gedrückt wird, ... (siehe Beispiel 2).

Wenn $bCheckModifierKey nicht wahr ist, gibt die Kombination aus einer „Modifikatortaste” + Taste 0 zurück,
und @extended wird gesetzt, wenn die Modifikatortaste gedrückt wird: 1 = SHIFT, 2 = CTRL, 3 = ALT, 4 = WIN, 5 = rechte WIN (siehe Beispiel 2).

Wenn $bCheckModifierKey = True ist, erfolgt die Rückgabe, wenn die „Modifikatortaste” losgelassen wird.
Wenn $bCheckModifierKey = -1 ist, erfolgt die Rückgabe, wenn die „Modifikatortaste” gedrückt wird.

_IsPressed() gibt 1 zurück wenn die Taste losgelassen wurde.
Selbst kurze Tastendrücke können mehrfach innerhalb einer Schleife zurückgegeben werden.
Wenn der verwendete Code keine blockierende Funktion wie z. B. MsgBox enthält und der User keine mehrfachen Returns benötigt, so sollte das Skript warten bis _IsPressed() 0 zurückgibt bevor dieses fortfährt.

Siehe auch

Suche nach GetAsyncKeyState in der MSDN Bibliothek.

Beispiel

Beispiel 1: _Wird mit $vkey als Zeichenfolge ausgedrückt

#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIvkeysConstants.au3>

Local $hDLL = DllOpen("user32.dll")

While 1
    If _IsPressed("10", $hDLL) Then
        ConsoleWrite("_IsPressed - Shift-Taste wurde gedrückt. @extended = " & @extended & @CRLF)
        ; Wartet bis die Taste wieder losgelassen wurde.
        While _IsPressed("10", $hDLL)
            Sleep(100)
        WEnd
        ConsoleWrite("_IsPressed - Shift-Taste wurde losgelassen. @extended = " & @extended & @CRLF)
    ElseIf _IsPressed("1B", $hDLL) Then
        ConsoleWrite("_IsPressed - Esc-Taste wurde gedrückt. @extended = " & @extended & @CRLF)
        MsgBox($MB_SYSTEMMODAL, "_IsPressed", "Da Esc-Taste gedrückt wurde wird die Anwendung beendet.", 3)
        ExitLoop
    EndIf
    Sleep(100)
WEnd

DllClose($hDLL)

Example 2 : _IsPressed using $vkey as array with modifier key checking

#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIvkeysConstants.au3>

Local $asModifierKeys[6] = [0, "VK_SHIFT", "VK_CONTROL", "VK_MENU", "VK_LWIN", "VK_RWIN"]

Local $aKeys[3] = [$VK_ESCAPE, $VK_LBUTTON, $VK_TAB]
While 1
    Local $iRet = _IsPressed($aKeys, Default, True) ; Check modifier
    If Not $iRet And @extended Then ConsoleWrite("The modifier key " & $asModifierKeys[@extended] & " has been pressed. @extended = " & @extended & @CRLF)

    Local $sKey
    Switch $iRet
        Case 1 ; Keyboard ESC
            $sKey = "{ESCAPE}"
            ExitLoop

        Case 2 ; MouseClick Left
            $sKey = "{LBUTTON}"
            ExitLoop

        Case 3 ; Keyboard Tab
            $sKey = "{TAB}"
            ExitLoop

    EndSwitch

    Sleep(100)
WEnd

_IsPressed() ; to DLLClose the default Dll created by the previous _IsPressed_(...)

Send("^z") ; to avoid change in the Scite Window

ConsoleWrite("The key " & $sKey & " has been pressed." & @CRLF)
MsgBox($MB_SYSTEMMODAL, "Result", "The key " & $sKey & " has been pressed.", 2)

Example 3 : _Ispressed using $vkey as integer with modifier key checking

#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIvkeysConstants.au3>

Example()
Func Example()
    While 1
        If _IsPressed($VK_F2, Default, True) Then
            ConsoleWrite("_IsPressed - F2 (without any modifier keys pressed) was pressed." & @CRLF)
            ; Wait until key is released.
            While _IsPressed($VK_F2, Default, True)
                Sleep(100)
            WEnd
            ConsoleWrite("_IsPressed - F2 (without any modifier keys pressed) was released." & @CRLF)
        ElseIf _IsPressed($VK_ESCAPE) Then
            MsgBox($MB_SYSTEMMODAL, "_IsPressed", "The Esc Key was pressed, therefore we will close the application.", 3)
            ExitLoop
        EndIf
        Sleep(100)
    WEnd

    _IsPressed() ; to release the internal handle created by previous call to _IsPressed(...)

EndFunc   ;==>Example