Funktionreferenz


_Net_Share_FileEnum

Beschreibung anzeigen in

Gibt Informationen über die geöffnete Datei auf dem Server zurück

#include <NetShare.au3>
_Net_Share_FileEnum ( [$sServer = "" [, $sBaseName = "" [, $sUserName = ""]]] )

Parameter

$sServer [optional] String der den Namen des Server beinhaltet auf dem die Funktion ausgeführt wird.
Ein leerer String spezifiziert den lokalen Computer.
$sBaseName [optional] String beinhaltet den Ausdruck der zurückgegebenen Informationen.
Wenn er leer ist sind alle offenen Ressourcen aufgezählt.
Wenn er nicht leer ist, zählt die Funktion nur Ressourcen auf, die den $sBaseName als Präfix besitzen.
$sUserName [optional] String der den Benutzernamen spezifiziert. Wenn $sUserName nicht leer ist,
dient er als Abfragekriterium für die Aufzählung.

Rückgabewert

Erfolg: Ein Array mit dem folgenden Format:
    [0][0] - Anzahl der Einträge im Array(n)
    [1][0] - ID die der Ressource zugeteilt wird wenn sie geöffnet ist.
    [1][1] - Zugriffsberechtigungen für die auszuführende Ressource:
   1 - Berechtigung zum lesen und ausführen einer Ressource.
   2 - Berechtigung zum schreiben einer Ressource.
   4 - Berechtigung zum erstellen einer Ressource.
   8 - Berechtigung zum ausführen.
  16 - Berechtigung zum löschen.
  32 - Berechtigung zum Rechte ändern.
  64 - Ändern der ACL Berechtigungen
    [1][2] - Beinhaltet die maximale Anzahl der Dateien.
    [1][3] - Spezifiziert den Pfad zu der geöffneten Ressource.
    [1][4] - Spezifiziert welcher Benutzer an welchem Computer die Ressource geöffnet hat.
Fehler: Setzt das @error Flag auf ungleich null.

Bemerkungen

Nur Mitglieder der Lokalen-Gruppe Administratoren oder Server-Operater können diese Funktion ausführen.

Verwandte Funktionen

_Net_Share_ConnectionEnum, _Net_Share_SessionEnum, _Net_Share_ShareEnum

Siehe auch

Suche nach NetFileEnum in der MSDN Bibliothek.

Beispiel

#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $aInfo

    ; Erstellt eine GUI
    GUICreate("NetShare", 400, 300)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermitteln der Server und Freigabe Informationen
    $sServer = InputBox("Netzwerk Demo", "Server Namen eingeben:", "\\MeinServer", "", 200, 130)
    If @error Then Exit

    ; Auflisten der freigegebenen Dateien auf dem Server
    $aInfo = _Net_Share_FileEnum($sServer)
    MemoWrite("Fehler ....................: " & @error)
    MemoWrite("Einträge lesen ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Ressource ID ................: " & $aInfo[$iI][0])
        MemoWrite("Ressource Benutzerrechte ....: " & _Net_Share_PermStr($aInfo[$iI][1]))
        MemoWrite("Ressource Sperren ...........: " & $aInfo[$iI][2])
        MemoWrite("Ressource Pfad ..............: " & $aInfo[$iI][3])
        MemoWrite("Ressource Benutzer ..........: " & $aInfo[$iI][4])
        MemoWrite()
    Next

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite