Funktionreferenz

_Net_Share_PermStr

Beschreibung anzeigen in

Gibt die als Integer übergebene Berechtigung einer Ressource als String zurück

#include <NetShare.au3>
_Net_Share_PermStr ( $iPerm )

Parameter

$iPerm Berechtigungen der Ressource:
    1 - Erlaubnis, Daten aus einer Ressource zu lesen und auszuführen.
    2 - Erlaubnis, Daten in die Ressource zu schreiben.
    4 - Erlaubnis, eine neue Instanz einer Ressource zu erzeugen.
    8 - Erlaubnis, die Ressource auszuführen.
    16 - Erlaubnis, die Ressource zu löschen.
    32 - Erlaubnis, die Eigenschaften der Ressource zu verändern.
    64 - Erlaubnis, die einer Ressource zugewiesenen Berechtigungen zu ändern.

Rückgabewert

Gibt eine Berechtigung der Ressource als String (englisch) zurück

Beispiel

#include <GuiConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $aInfo

    ; Erstellt eine GUI
    GUICreate("NetShare", 400, 300)

    ; Erstellt ein Memo Control
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ermitteln der Server und Freigabe Informationen
    $sServer = InputBox("Netzwerk Demo", "Server Namen eingeben:", "\\MeinServer", "", 200, 130)
    If @error Then Exit

    ; Auflisten der freigegebenen Dateien auf dem Server
    $aInfo = _Net_Share_FileEnum($sServer)
    MemoWrite("Fehler ....................: " & @error)
    MemoWrite("Einträge lesen ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Ressource ID ................: " & $aInfo[$iI][0])
        MemoWrite("Ressource Benutzerrechte ....: " & _Net_Share_PermStr($aInfo[$iI][1]))
        MemoWrite("Ressource Sperren ...........: " & $aInfo[$iI][2])
        MemoWrite("Ressource Pfad ..............: " & $aInfo[$iI][3])
        MemoWrite("Ressource Benutzer ..........: " & $aInfo[$iI][4])
        MemoWrite()
    Next

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite