GUICtrlSetFont
Beschreibung anzeigen in
Setzt die Schriftart und Schriftgröße für ein Control.
GUICtrlSetFont ( controlID, size [, weight [, attribute [, fontname [, quality]]]] )
Parameter
| ControlID | Die Identifikationsnummer des Controls (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben, oder -1 für das zuletzt erzeugte Control. |
| size | Schriftgröße (Standard ist 8.5) |
| weight | [optional] Schriftstärke im Bereich von 0 bis 1000. Z.B.: 400 ist 'normal' und 700 ist 'bold'. Ist der Wert 0 dann wird ein Standardwert benutzt. Der Einfachheit Halber stehen folgende Werte zur Verfügung: $FW_DONTCARE = 0 (Standard Schriftstärke wird verwendet) $FW_THIN = 100 $FW_EXTRALIGHT = 200 $FW_LIGHT = 300 $FW_NORMAL = 400 $FW_MEDIUM = 500 $FW_SEMIBOLD = 600 $FW_BOLD = 700 $FW_EXTRABOLD = 800 $FW_HEAVY = 900 Die Konstanten sind in FontConstants.au3 definiert. |
| attribute | [optional] Definiert den Stil (durch Addieren der Werte können mehrere Stile kombiniert werden). $GUI_FONTNORMAL (0) = Normal $GUI_FONTITALIC (2) = Italic $GUI_FONTUNDER (4) = Unterstrichen $GUI_FONTSTRIKE (8) = Durchgestrichen Die Konstanten sind in GUIConstantsEx.au3 definiert. |
| fontname | [optional] Name der gewünschten Schriftart. (Der im Betriebssystem als Standard definierte GUI Font wird benutzt wenn fontname "" ist, oder nicht gefunden wird) |
| quality | [optional] Qualität der Schrift. Auszuwählen aus: $DEFAULT_QUALITY (0) = Das Erscheinungsbild des Fonts spielt keine Rolle. $DRAFT_QUALITY (1) = Das Erscheinungsbild ist weniger wichtig als wenn $PROOF_QUALITY benutzt wird. Für GDI raster fonts ist Skalieren erlaubt, was bedeuted das mehrere Schriftgrößen verfügbar sind, aber die Qualität schlechter sein kann. Fall notwendig werden Bold, Italic, unterstrichen und durchgestrichen Schrifstil synthetisch erzeugt. $PROOF_QUALITY (2) = (Standard) Zeichenqualität ist wichtiger als genaues einhalten der logischen Zeichenattribute. Für GDI raster fonts ist Skalieren verboten und der Font mit der annähernd richtigen Größe wird verwendet. Auch wenn die Größe nicht genau passt, die Qualität des Font ist hoch und das Schriftbild ist nicht gestört. Fall notwendig werden Bold, Italic, unterstrichen und durchgestrichen Schrifstil synthetisch erzeugt. $NONANTIALIASED_QUALITY (3) = Font wird nie geglättet(anti aliased). $ANTIALIASED_QUALITY (4) = Wenn es der Font unterstützt wird immer geglättet(anti aliased) und die Schriftgröße ist nie zu klein oder groß. $CLEARTYPE_QUALITY (5) = Wenn möglich wird der Text mit der ClearType Methode geglättet. Siehe die Bermerkungen auf der MSDN Seite für LOGFONT für Details wenn ClearType ist nicht verfügbar. Wenn weder $ANTIALIASED_QUALITY noch $NONANTIALIASED_QUALITY ausgewählt, wird der Font nur geglättet wenn in der Systemsteuerung die "Kantenglättung für Bildschrimschriftarten" ausgewählt wurde. Die Konstanten sind in FontConstants.au3 definiert. |
Rückgabewert
| Erfolg: | 1. |
| Fehler: | 0. |
Bemerkungen
Standardmäßig wird für Controls die Schriftart verwendet, die durch GUISetFont() festgelegt wurde.
Im Anhang ist eine komplette Liste der Schriftarten und der Betriebssysteme, die sie unterstützen, zu finden.
Die Schriftgröße kann als Dezimalwert angegeben werden, wie z.B. 8.5.
Für manche Controls wie zum Beispiel Labels kann die Standardgröße 8.5 anstatt 9 sein, je nach dem aktuell verwendeten Windows-Stil.
Für mehr Hilfe zum Parameter "Quality" siehe MSDN, manche Windows XP Installationen benötigen CLEARTYPE_QUALITY=5
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Verwendete Schriftart der Controls.
Local Const $sFont = "Comic Sans Ms"
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Beispiel", 300, 200)
; Erstellt Label-Controls.
GUICtrlCreateLabel("Ein unterstrichener Textstring", 10, 10, 185, 17)
GUICtrlSetFont(-1, 9, $FW_NORMAL, $GUI_FONTUNDER, $sFont) ; Setzt die Schrift des vorherigen Controls.
Local $idLabel2 = GUICtrlCreateLabel("Ein kursiver Textstring", 10, 30, 185, 17)
GUICtrlSetFont($idLabel2, 9, $FW_NORMAL, $GUI_FONTITALIC, $sFont) ; Setzt die Schrift der ControlID die in $iLabel2 gespeichert wurde.
Local $idLabel3 = GUICtrlCreateLabel("Ein durchgestrichenerr Textstring", 10, 50, 290, 17)
GUICtrlSetFont($idLabel3, 9, $FW_NORMAL, $GUI_FONTSTRIKE, $sFont) ; Setzt die Schrift der ControlID die in $iLabel3 gespeichert wurde.
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 170, 85, 25)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
EndFunc ;==>Example