_WinAPI_SetSysColors

Beschreibung anzeigen in

Setzt Informationen über die angezeigten Geräte in einem System

#include <WinAPISysWin.au3>
_WinAPI_SetSysColors ( $vElements, $vColors )

Parameter

$vElements	einzelnes Element oder Array mit Elementen
$vColors	Einzelne Farbe oder Array mit Farben

Rückgabewert

Erfolg:	True
Fehler:	False. Es ist _WinAPI_GetLastError() aufzurufen um erweiterte Fehlerinformationen zu erhalten.

Bemerkungen

Siehe _WinAPI_GetSysColor() für eine Liste mit Elementindizes und Anforderungen.

Siehe auch

Suche nach SetSysColors in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aElements[2] = [$COLOR_ACTIVECAPTION, $COLOR_GRADIENTACTIVECAPTION]
    ; Rot und Gelb
    Local $aColors[2] = [255, 65535], $aSaveColors[2]

    GUICreate("Meine GUI", 300, 200)

    $aSaveColors[0] = _WinAPI_GetSysColor($COLOR_ACTIVECAPTION)
    $aSaveColors[1] = _WinAPI_GetSysColor($COLOR_GRADIENTACTIVECAPTION)

    _WinAPI_SetSysColors($aElements, $aColors)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete()

    _WinAPI_SetSysColors($aElements, $aSaveColors)

    Exit
EndFunc   ;==>Example