Trans + LayeredAttributes

  • Hey ho!
    Also ich hab 2 Guis.. Bei der Child Gui, welche ontop liegt, hab ich mit den LayeredAttributes von progandy die Hauptfarbe transparent gemacht,
    um die main-Gui sehen zu können!
    Doch ich will jetzt nicht nur die eine Farbe transparent machen, sondern mit einem Slider die Transparenz der ganzen Gui bestimmen! Das heißt die Gui soll abwechselnd transparent und sichtbar sein, aber die eine LayeredAttribute Farbe soll >immer< transparent bleiben!
    So und hier kommt mein Problem: Immer wenn ich die Transparenz per Slider verstelle wird wieder die transparente LayeredAttributes Farbe resettet...

    Hier ein Beispiel zum Austoben ->

    Spoiler anzeigen
    [autoit]

    #include <GUIConstantsEx.au3>
    #include <SliderConstants.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GuiOnEventMode", 1)
    ; #GUI# =================================================================================
    $titel = "Transparenz/Slider Beispiel"
    $hGui = GUICreate($titel, 260, 105,-1,-1,-1,$WS_EX_LAYERED)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    GuiSetBkColor(0xABCDEF)
    _API_SetLayeredWindowAttributes($hGui,0xABCDEF,255,False)
    GUICtrlCreateGroup("", 15, 15, 230, 70)
    $label = GUICtrlCreateLabel("Durchsichtig = 0%", 23, 27, 100, 14)
    $slider = GUICtrlCreateSlider(23, 57, 200, 20, BitOR($TBS_AUTOTICKS, $WS_BORDER))
    GUICtrlSetData($slider, 0)
    GUISetState()
    GUIRegisterMsg($WM_HSCROLL, "WM_HVSCROLL")

    [/autoit] [autoit][/autoit] [autoit]

    ; #MAIN LOOP# ============================================================================
    While 1
    Sleep(100)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTIONS# ============================================================================
    ;Wenn Slider verstellt wird, wird wieder die blaue Bk-Farbe sichtbar!
    Func WM_HVSCROLL($hwnd, $iMsg, $wParam, $lParam) ; Slider
    Local $hWndFrom, $iCode
    If Not IsHWnd($slider) Then $hWndCombo1 = GUICtrlGetHandle($slider)
    $hWndFrom = $lParam
    Switch $hWndFrom
    Case $slider, $hWndCombo1
    GUICtrlSetData($label, "Durchsichtig = " & GUICtrlRead($slider) & "%")
    WinSetTrans($titel, "", 255-GUICtrlRead($slider) * 2.55)
    EndSwitch
    EndFunc ;==>WM_HVSCROLL

    [/autoit] [autoit][/autoit] [autoit]

    ;===============================================================================
    ;
    ; Function Name: _API_SetLayeredWindowAttributes
    ; Description:: Sets Layered Window Attributes:) See MSDN for more informaion
    ; Parameter(s):
    ; $hwnd - Handle of GUI to work on
    ; $i_transcolor - Transparent color
    ; $Transparency - Set Transparancy of GUI
    ; $isColorRef - If True, $i_transcolor is a COLORREF-Strucure, else an RGB-Color
    ; Requirement(s): Layered Windows
    ; Return Value(s): Success: 1
    ; Error: 0
    ; @error: 1 to 3 - Error from DllCall
    ; @error: 4 - Function did not succeed - use
    ; _WinAPI_GetLastErrorMessage or _WinAPI_GetLastError to get more information
    ; Author(s): Prog@ndy
    ;
    ;===============================================================================
    ;
    Func _API_SetLayeredWindowAttributes($hwnd, $i_transcolor, $Transparency = 255, $isColorRef = False)
    Local Const $AC_SRC_ALPHA = 1
    Local Const $ULW_ALPHA = 2
    Local Const $LWA_ALPHA = 0x2
    Local Const $LWA_COLORKEY = 0x1
    If Not $isColorRef Then
    $i_transcolor = Hex(String($i_transcolor), 6)
    $i_transcolor = Execute('0x00' & StringMid($i_transcolor, 5, 2) & StringMid($i_transcolor, 3, 2) & StringMid($i_transcolor, 1, 2))
    EndIf
    Local $Ret = DllCall("user32.dll", "int", "SetLayeredWindowAttributes", "hwnd", $hwnd, "long", $i_transcolor, "byte", $Transparency, "long", $LWA_COLORKEY + $LWA_ALPHA)
    Select
    Case @error
    Return SetError(@error, 0, 0)
    Case $Ret[0] = 0
    Return SetError(4, 0, 0)
    Case Else
    Return 1
    EndSelect
    EndFunc ;==>_API_SetLayeredWindowAttributes

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    Exit
    EndFunc ;==>_Exit

    [/autoit]
  • du musst für die Transparenz immer die SetLayeredWindowAttributes verwenden und nicht WinSetTrans ;)

  • Wie soll ich denn mit den LayeredAttributes alle Farben, die auf der Gui sind transparent und sichtbar machen und 1 Farbe gleichzeitig immer transparent halten? ?(

  • So:

    [autoit]

    _API_SetLayeredWindowAttributes($hGui,$TransColor, 255-GUICtrlRead($slider) * 2.55)

    [/autoit]
  • Lol das sieht vielversprechend aus :D Muss es heute abend richtig testen!
    Hätte nich gedacht das das so einfach ist..