Moin Moin
mit @DesktopHeight und @DesktopWidth kann man die auflösung des ersten monitors auslesen. für den 2ten monitor geht das leider nicht 
kennt irgendjemand ne möglichkeit die auflösung des 2ten oder 3ten (falls noch einer dazu kommt ^^) auszulesen?
mfg
Teste das mal (kann nicht testen - hab nur einen Monitor):
#include <Array.au3>
[/autoit] [autoit][/autoit] [autoit]$Monitore = _GetMonitors()
If Not @error Then _ArrayDisplay($Monitore)
Func _GetMonitors()
Local $cbMonitorEnumProc = DllCallbackRegister("MonitorEnumProc", "ubyte", "ptr;ptr;ptr;int")
If @error Then Return SetError(1, 0, False)
Local $strctCount = DllStructCreate("uint Count;uint Width[12];uint Height[12]")
If @error Then Return SetError(2, @error, False)
Local $iCount
DllStructSetData($strctCount, "Count", 0)
$Ret = DllCall("User32.dll", "ubyte","EnumDisplayMonitors","ptr", 0,"ptr", 0, "ptr", DllCallbackGetPtr($cbMonitorEnumProc), "ptr", DllStructGetPtr($strctCount))
If @error Or $Ret[0] = 0 Then Return SetError(3, @error, False)
DllCallbackFree($cbMonitorEnumProc)
$iCount = Int(DllStructGetData($strctCount, "Count"))
Local $aMonitors[$iCount+1][2] = [[$iCount,0]]
For $i = 1 To $iCount
$aMonitors[$i][0] = DllStructGetData($strctCount, "Width",$i)
$aMonitors[$i][1] = DllStructGetData($strctCount, "Height",$i)
Next
Return $aMonitors
EndFunc
Func MonitorEnumProc($hMonitor, $hdcMonitor, $lprcMonitor, $dwData)
Local $strctRECT = DllStructCreate("long left;long top;long right;long bottom", $lprcMonitor)
Local $strctCount = DllStructCreate("uint Count;uint Width[12];uint Height[12]", $dwData)
Local $iNumber = DllStructGetData($strctCount, "Count")
Local $Height = Int(DllStructGetData($strctRECT, "bottom"))-Int(DllStructGetData($strctRECT, "top"))
Local $Width = Int(DllStructGetData($strctRECT, "right"))-Int(DllStructGetData($strctRECT, "left"))
DllStructSetData($strctCount, "Width", $Width, $iNumber+1)
DllStructSetData($strctCount, "Height", $Height, $iNumber+1)
DllStructSetData($strctCount, "Count", $iNumber+1)
Return True
EndFunc
jap funzt fette sache thx 
ich bin nicht so der held darin, fragen sollte mir wieterhelfen:
ich hab 2 anzeigen und niemand hat hier gesagt was passiert wenn nur eine da ist....
es is an zu nehmen das dies in allen situationen funktioniert, aber ich möchte mir mal sicher sein...
Stimmt - Fragen sollten dir weiterhelfen - einfach mal kurz ausprobieren ist was für Anfänger... :pinch:
Ja - es funktioniert natürlich auch mit nur einem Monitor (selbst bei keinem Monitor würde es funktionieren...)
Aber ganz ehrlich: Findest du das nicht auch ein bisschen merkwürdig so ne Frage zu stellen anstatt einfach mal kurz zu testen?... 
einen Laptop hätte ich schon um es mit einer anzeige zu testen, aber den muss ich erst einrichten, und das lohnt sich nicht
und dem PC will ich die sekundäre anzeige nich weg nehmen nur um was zu testen 
fragen is da die einfachste lösung 
also danke dir 
das programm wird also bei 100 anzeigen sogar besser als die grafik funktionieren
das programm wird also bei 100 anzeigen sogar besser als die grafik funktionieren
12 Monitore ist das Maximum - so wie ich das Skript hier geschrieben habe.
Ändern kannst du diese Anzahl jeweils in dem du die Größe der Arrays in der Struktur $strctCount entsprechend anpasst.
