Modern Menu Unverständlich...

    Hallo Liebe Auoit Gemeinde ich wollte mir ein traymenu schreiben mit icons usw. doch ich verstehe keine einzige der Funktionen der ModernMenu.au3.

    wäre evtl. jemand so freundlich mir zu helfen damit er mir mal ein einfaches Trymenu mit dieser au3 schreibt ?

    ich Poste mal das normale Traymenu dazu

    MFG Eistee

    Spoiler anzeigen
    [autoit]

    Opt("TrayMenuMode",1)
    $Set = TrayCreateMenu("Settings")
    $Set2 = TrayCreateMenu("HotKeys",$Set)
    $Set3 = TrayCreateMenu("Lokalisten",$Set)
    $HotOn = TrayCreateItem("Hotkeys Aktivieren",$Set2)
    $HotOff = TrayCreateItem("Hotkeys Deaktivieren",$Set2)
    $URL = TrayCreateItem("URL´s Bearbeiten",$Set)
    $LOK = TrayCreateItem("Benutzer Daten ändern",$Set3)
    $AB = TrayCreateItem("About")
    $EX = TrayCreateItem("Beenden")
    TraySetState()

    [/autoit]

    Hio
    ---------------------
    Habe dir mal ein ModernTrayMenu Geschrieben, und es ausführlich beschrieben *buh

    Hab mich zwar nicht genau an die Punkte gehalten die du möchtest, aber ich glaube/hoffe so ist es verständlicher...


    Spoiler anzeigen
    [autoit]

    #NoTrayIcon ;das das normale Trayicon versteckt wird, da sonst 2 icons im Tray wären (Modern und Normal)
    #include <ModernMenu.au3> ;wichtig *gg*

    [/autoit] [autoit][/autoit] [autoit]

    ;==================Create the tray icon======================
    $nTrayIcon1 = _TrayIconCreate("Das ist ein Modern-Tray-Menu", "shell32.dll", -15) ;Trayicon Tooltip & Icon
    _TrayIconSetClick(-1, 16) ;Das TrayMenü wird nur durch rechtsklick geöffnet
    _TrayIconSetState() ;Setzt den Status des TrayIcons auf Show
    _TrayTip($nTrayIcon1,"info","Right-Click for more options",3000,1) ;ModernTrayIcon Tooltip
    ;============================================================

    [/autoit] [autoit][/autoit] [autoit]

    ;=======================Tray-Hauptmenü=======================
    $TrayMenu = _TrayCreateContextMenu(-1) ;Grundbaustein ModernTray - Menu // ; is the same like _TrayCreateContextMenu(-1) or _TrayCreateContextMenu($nTrayIcon1)
    ;============================================================

    [/autoit] [autoit][/autoit] [autoit]

    ;=================vertikale Tray-Taskleiste==================
    $Side = _CreateSideMenu($TrayMenu) ;Vertikaler Seiteleiste am Traymenu (Grundbaustein)
    _SetSideMenuText($Side, "Test") ;Vertikaler Seiteleiste am Traymenu (Text)
    _SetSideMenuColor($Side, 0x00FFFF) ;Vertikaler Seiteleiste am Traymenu (Textfarbe hex)
    _SetSideMenuBkColor($Side, 0x802222) ;Vertikaler Seiteleiste am Traymenu (Hintergrundfarbe 1 )
    _SetSideMenuBkGradColor($Side, 0x4477AA) ;Vertikaler Seiteleiste am Traymenu (Hintergrundfarbe 2 )
    ;=============================================================

    [/autoit] [autoit][/autoit] [autoit]

    ;==================TrayMenüpunkt mit Untermenü================
    $TrayMenu_MsgBox = _TrayCreateMenu("Messagebox") ;HauptMenü "$TrayMenu_MsgBox"
    $Msg1 = _TrayCreateItem("Msgbox 1",$TrayMenu_MsgBox) ;UnterMenü von $TrayMenu_MsgBox
    $Msg2 = _TrayCreateItem("Msgbox 2",$TrayMenu_MsgBox) ;UnterMenü von $TrayMenu_MsgBox
    ;=============================================================
    ;===================Weitere Tray Menüpunkte===================
    $TrayInfo = _TrayCreateItem("info") ; meine info Function
    $TrayExit = _TrayCreateItem("Exit") ; meine Exit Function
    ;=============================================================

    [/autoit] [autoit][/autoit] [autoit]

    ;=====================TrayItem mit Icon versehen==============
    _TrayItemSetIcon($TrayMenu_MsgBox, "shell32.dll", -44) ;icons sind Systemicons, können auch normale verwendet werden zb. ("Icon1.ico")
    _TrayItemSetIcon($TrayInfo, "shell32.dll", -24)
    _TrayItemSetIcon($TrayExit, "shell32.dll", -28)
    ;=============================================================

    [/autoit] [autoit][/autoit] [autoit]

    ;============TrayMenü Funktionen==========
    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $TrayExit
    Exit
    Case $TrayInfo
    _TrayTip($nTrayIcon1,"info","Das ist ein Test",3000,1) ;Ziemlich gleich wie beim classischen TrayTip
    Case $Msg1
    MsgBox (0,"MessageBox1","lala")
    Case $Msg2
    MsgBox (64,"MessageBox2","Das ist sinnlose info Message")
    EndSwitch
    WEnd
    ;===========================================

    [/autoit]

    Und du kannst auch bei meinen Programm nachschauen...,
    da ist das TrayMenu etwas ausführlicher: http://www.autoit.de/index.php?page=Thread&threadID=13567


    // Mfg. Freeðøm 

    4 Mal editiert, zuletzt von Freeðøm (29. Juli 2009 um 00:00)